{ lib
, buildPythonPackage
, fetchFromGitHub
, pythonRelaxDepsHook
, flit-core

# Core dependencies
, pycountry
, python-stdnum
, unidecode
, redisearch
, rapidfuzz

# Integration dependencies
, gocardless-pro
, googlemaps
, plaid-python
, python-youtube
, taxjar
, tweepy
}:
let
  pinData = import ../srcs/pin.nix;
  inherit (pinData) erpnextVersion;
  inherit (pinData.hashes) erpnextSrcHash;
in
buildPythonPackage rec {
  pname = "erpnext";
  version = erpnextVersion;

  src = fetchFromGitHub {
    owner = "frappe";
    repo = pname;
    rev = "v${erpnextVersion}";
    sha256 = erpnextSrcHash;
  };

  format = "pyproject";

  nativeBuildInputs = [ pythonRelaxDepsHook flit-core ];
  pythonRelaxDeps = [
    "pycountry"
    "rapidfuzz"
    "Unidecode"
  ];

  propagatedBuildInputs = [
    # Core dependencies
    pycountry
    python-stdnum
    unidecode
    redisearch
    rapidfuzz

    # Integration dependencies
    gocardless-pro
    googlemaps
    plaid-python
    python-youtube
    taxjar
    tweepy
  ];
}