From 3c78e7a3e5f96cd5a3c5e32f030f31e1d8b12c4a Mon Sep 17 00:00:00 2001
From: Robert Helgesson <robert@rycee.net>
Date: Thu, 1 Jan 2015 16:34:58 +0100
Subject: [PATCH] Add package 'svtplay-dl'.

---
 pkgs/tools/misc/svtplay-dl/default.nix | 42 ++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix        |  4 +++
 2 files changed, 46 insertions(+)
 create mode 100644 pkgs/tools/misc/svtplay-dl/default.nix

diff --git a/pkgs/tools/misc/svtplay-dl/default.nix b/pkgs/tools/misc/svtplay-dl/default.nix
new file mode 100644
index 00000000000..60f012d01e2
--- /dev/null
+++ b/pkgs/tools/misc/svtplay-dl/default.nix
@@ -0,0 +1,42 @@
+{ stdenv, fetchurl, makeWrapper, python, perl, zip
+, rtmpdump, nose, mock, pycrypto, substituteAll }:
+
+stdenv.mkDerivation rec {
+  name = "svtplay-dl-${version}";
+  version = "0.10.2014.12.26";
+
+  src = fetchurl {
+    url = "https://github.com/spaam/svtplay-dl/archive/${version}.tar.gz";
+    sha256 = "0zz57n4zjgj9wcbawwi8drqyxf7myhlz2x3a7vzc5ccaz66fl9ps";
+  };
+
+  pythonPaths = [ pycrypto ];
+  buildInputs = [ python perl nose mock rtmpdump makeWrapper ] ++ pythonPaths;
+  nativeBuildInputs = [ zip ];
+
+  postPatch = ''
+    substituteInPlace lib/svtplay_dl/fetcher/rtmp.py \
+      --replace '"rtmpdump"' '"${rtmpdump}/bin/rtmpdump"'
+
+    substituteInPlace run-tests.sh \
+      --replace 'PYTHONPATH=lib' 'PYTHONPATH=lib:$PYTHONPATH'
+  '';
+
+  makeFlags = "PREFIX=$(out) SYSCONFDIR=$(out)/etc PYTHON=${python}/bin/python";
+
+  postInstall = ''
+    wrapProgram "$out/bin/svtplay-dl" \
+      --prefix PYTHONPATH : "$PYTHONPATH"
+  '';
+
+  doCheck = true;
+  checkPhase = "sh run-tests.sh -2";
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/spaam/svtplay-dl;
+    description = "Command-line tool to download videos from svtplay.se and other sites";
+    license = licenses.mit;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = [ maintainers.rycee ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index a2e87913768..6945e84e1ac 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2500,6 +2500,10 @@ let
 
   svnfs = callPackage ../tools/filesystems/svnfs { };
 
+  svtplay-dl = callPackage ../tools/misc/svtplay-dl {
+    inherit (pythonPackages) nose mock;
+  };
+
   sysbench = callPackage ../development/tools/misc/sysbench {};
 
   system_config_printer = callPackage ../tools/misc/system-config-printer {