Merge pull request #179752 from hqurve/cantor

init labplot, cantor and supporting libraries

pkgs/applications/kde/analitza.nix

@@ -0,0 +1,34 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, qtbase
+, qtsvg
+, eigen
+, kdoctools
+, qttools
+}:
+
+mkDerivation {
+  pname = "analitza";
+
+  nativeBuildInputs = [
+    cmake
+    eigen
+    extra-cmake-modules
+    kdoctools
+    qttools
+  ];
+
+  buildInputs = [
+    qtbase
+    qtsvg
+  ];
+
+  meta = with lib; {
+    description = "Front end to powerful mathematics and statistics packages";
+    homepage = "https://cantor.kde.org/";
+    license = with licenses; [ gpl2Only lgpl2Only fdl12Only ];
+    maintainers = with maintainers; [ hqurve ];
+  };
+}

pkgs/applications/kde/cantor.nix

@@ -0,0 +1,109 @@
+{ lib
+, mkDerivation
+
+, cmake
+, extra-cmake-modules
+, makeWrapper
+, shared-mime-info
+
+, qtbase
+, qtsvg
+, qttools
+, qtwebengine
+, qtxmlpatterns
+
+, poppler
+
+, karchive
+, kcompletion
+, kconfig
+, kcoreaddons
+, kcrash
+, kdoctools
+, ki18n
+, kiconthemes
+, kio
+, knewstuff
+, kparts
+, kpty
+, ktexteditor
+, ktextwidgets
+, kxmlgui
+, syntax-highlighting
+
+, libspectre
+
+# Backends. Set to null if you want to omit from the build
+, withAnalitza ? true, analitza
+, wtihJulia ? true, julia
+, withQalculate ? true, libqalculate
+, withLua ? true, luajit
+, withPython ? true, python3
+, withR ? true, R
+, withSage ? true, sage, sage-with-env ? sage.with-env
+}:
+
+mkDerivation {
+  pname = "cantor";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    makeWrapper
+    shared-mime-info
+    qttools
+  ];
+
+  buildInputs = [
+    qtbase
+    qtsvg
+    qtwebengine
+    qtxmlpatterns
+
+    poppler
+
+    karchive
+    kcompletion
+    kconfig
+    kcoreaddons
+    kcrash
+    kdoctools
+    ki18n
+    kiconthemes
+    kio
+    knewstuff
+    kparts
+    kpty
+    ktexteditor
+    ktextwidgets
+    kxmlgui
+    syntax-highlighting
+
+    libspectre
+  ]
+  # backends
+  ++ lib.optional withAnalitza analitza
+  ++ lib.optional wtihJulia julia
+  ++ lib.optional withQalculate libqalculate
+  ++ lib.optional withLua luajit
+  ++ lib.optional withPython python3
+  ++ lib.optional withR R
+  ++ lib.optional withSage sage-with-env
+  ;
+
+  qtWrapperArgs = [
+    "--prefix PATH : ${placeholder "out"}/bin"
+  ];
+
+  postInstall = lib.optionalString withSage ''
+    wrapProgram $out/share/cantor/sagebackend/cantor-execsage \
+      --prefix PATH : ${sage-with-env}/bin
+  '';
+
+  meta = with lib; {
+    description = "Front end to powerful mathematics and statistics packages";
+    homepage = "https://cantor.kde.org/";
+    license = with licenses; [ bsd3 cc0 gpl2Only gpl2Plus gpl3Only ];
+    maintainers = with maintainers; [ hqurve ];
+  };
+}

pkgs/applications/kde/default.nix

@@ -72,12 +72,14 @@ let
       akonadi-search = callPackage ./akonadi-search.nix {};
       akonadiconsole = callPackage ./akonadiconsole.nix {};
       akregator = callPackage ./akregator.nix {};
+      analitza = callPackage ./analitza.nix {};
       ark = callPackage ./ark {};
       baloo-widgets = callPackage ./baloo-widgets.nix {};
       bomber = callPackage ./bomber.nix {};
       bovo = callPackage ./bovo.nix {};
       calendarsupport = callPackage ./calendarsupport.nix {};
       colord-kde = callPackage ./colord-kde.nix {};
+      cantor = callPackage ./cantor.nix {};
       dolphin = callPackage ./dolphin.nix {};
       dolphin-plugins = callPackage ./dolphin-plugins.nix {};
       dragon = callPackage ./dragon.nix {};

pkgs/applications/science/math/labplot/default.nix

@@ -0,0 +1,106 @@
+{ lib
+, stdenv
+, fetchurl
+, cmake
+, extra-cmake-modules
+, shared-mime-info
+, wrapQtAppsHook
+
+, qtbase
+
+, karchive
+, kcompletion
+, kconfig
+, kcoreaddons
+, kcrash
+, kdoctools
+, ki18n
+, kiconthemes
+, kio
+, knewstuff
+, kparts
+, ktextwidgets
+, kxmlgui
+, syntax-highlighting
+
+, gsl
+
+, poppler
+, fftw
+, hdf5
+, netcdf
+, cfitsio
+, libcerf
+, cantor
+, zlib
+, lz4
+, readstat
+, matio
+, qtserialport
+, discount
+}:
+
+stdenv.mkDerivation rec {
+  pname = "labplot";
+  version = "2.10.0";
+
+  src = fetchurl {
+    url = "https://download.kde.org/stable/labplot/labplot-${version}.tar.xz";
+    sha256 = "sha256-XfxnQxCQSkOHXWnj4mCh/t2WjmwbHs2rp1WrGqOMupA=";
+  };
+
+  cmakeFlags = [
+    # Disable Vector BLF since it depends on DBC parser which fails to be detected
+    "-DENABLE_VECTOR_BLF=OFF"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+    shared-mime-info
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    qtbase
+
+    karchive
+    kcompletion
+    kconfig
+    kcoreaddons
+    kcrash
+    kdoctools
+    ki18n
+    kiconthemes
+    kio
+    knewstuff
+    kparts
+    ktextwidgets
+    kxmlgui
+
+    syntax-highlighting
+    gsl
+
+    poppler
+    fftw
+    hdf5
+    netcdf
+    cfitsio
+    libcerf
+    cantor
+    zlib
+    lz4
+    readstat
+    matio
+    qtserialport
+    discount
+  ];
+
+  meta = with lib; {
+    description = "LabPlot is a FREE, open source and cross-platform Data Visualization and Analysis software accessible to everyone";
+    homepage = "https://labplot.kde.org";
+    license = with licenses; [ asl20 bsd3 cc-by-30 cc0 gpl2Only gpl2Plus gpl3Only gpl3Plus lgpl3Plus mit ];
+    maintainers = with maintainers; [ hqurve ];
+    platforms = platforms.unix;
+  };
+}

pkgs/applications/science/math/sage/sage.nix

@@ -49,6 +49,7 @@ stdenv.mkDerivation rec {
     quicktest = sage-tests.override { longTests = false; timeLimit = 600; }; # as many tests as possible in ~10m
     doc = sagedoc;
     lib = sage-with-env.env.lib;
+    with-env = sage-with-env;
     kernelspec = jupyter-kernel-definition;
   };
 

pkgs/top-level/all-packages.nix

@@ -37514,6 +37514,8 @@ with pkgs;
 
   brial = callPackage ../development/libraries/science/math/brial { };
 
+  cantor = libsForQt5.cantor;
+
   clblas = callPackage ../development/libraries/science/math/clblas {
     inherit (darwin.apple_sdk.frameworks) Accelerate CoreGraphics CoreVideo OpenCL;
   };
@@ -37532,6 +37534,8 @@ with pkgs;
 
   jags = callPackage ../applications/science/math/jags { };
 
+  labplot = libsForQt5.callPackage ../applications/science/math/labplot { };
+
   lapack = callPackage ../build-support/alternatives/lapack { };
 
   lapack-ilp64 = lapack.override { isILP64 = true; };