From 070dccae7bbb61166fabd7b1cea15c46894ac3aa Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Bj=C3=B8rn=20Forsman?= <bjorn.forsman@gmail.com>
Date: Sun, 28 Feb 2016 13:31:35 +0100
Subject: [PATCH] gitstats: init at 2016-01-08

Upstream does not make releases, using latest commit from master branch.
---
 .../version-management/gitstats/default.nix   | 39 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 41 insertions(+)
 create mode 100644 pkgs/applications/version-management/gitstats/default.nix

diff --git a/pkgs/applications/version-management/gitstats/default.nix b/pkgs/applications/version-management/gitstats/default.nix
new file mode 100644
index 00000000000..64b6e2107f6
--- /dev/null
+++ b/pkgs/applications/version-management/gitstats/default.nix
@@ -0,0 +1,39 @@
+{ stdenv, fetchzip, perl, python, gnuplot, coreutils, gnugrep }:
+
+stdenv.mkDerivation rec {
+  name = "gitstats-${version}";
+  version = "2016-01-08";
+
+  # upstream does not make releases
+  src = fetchzip {
+    url = "https://github.com/hoxu/gitstats/archive/55c5c285558c410bb35ebf421245d320ab9ee9fa.zip";
+    sha256 = "1bfcwhksylrpm88vyp33qjby4js31zcxy7w368dzjv4il3fh2i59";
+    name = name + "-src";
+  };
+
+  buildInputs = [ perl python ];
+
+  postPatch = ''
+    sed -e "s|gnuplot_cmd = .*|gnuplot_cmd = '${gnuplot}/bin/gnuplot'|" \
+        -e "s|\<wc\>|${coreutils}/bin/wc|g" \
+        -e "s|\<grep\>|${gnugrep}/bin/grep|g" \
+        -i gitstats
+  '';
+
+  buildPhase = ''
+    make man VERSION="${version}"
+  '';
+
+  installPhase = ''
+    make install PREFIX="$out" VERSION="${version}"
+    install -Dm644 doc/gitstats.1 "$out"/share/man/man1/gitstats.1
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = http://gitstats.sourceforge.net/;
+    description = "Git history statistics generator";
+    license = licenses.gpl2Plus;
+    platforms = platforms.all;
+    maintainers = [ maintainers.bjornfor ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index ef6dc1f6f3b..414fd2ae30a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1730,6 +1730,8 @@ let
 
   gitlab-workhorse = callPackage ../applications/version-management/gitlab-workhorse { };
 
+  gitstats = callPackage ../applications/version-management/gitstats { };
+
   git-latexdiff = callPackage ../tools/typesetting/git-latexdiff { };
 
   glusterfs = callPackage ../tools/filesystems/glusterfs { };