foomatic-db-ppds (cups ppd files): init
`foomatic-db-ppds` uses the Foomatic database from the packages `foomatic-db` and -- optionally -- `foomatic-db-nonfree` and the perl modules from `foomatic-db-engine` to generate about 8,800 ppd files. The general structure of the build recipe is as follows: * Merge `foomatic-db` and `foomatic-db-nonfree` into one package that represents the Foomatic database. The package `foomatic-db-nonfree` is optional as it taints the result license-wise; it will only be used if `withNonfreeDb` is to to `true` in the `callPackage` call. We create a tiny setup hook script that provides the combined database and sets an environment variable pointing to the database direcotry, which is expected by the foomatic engine. * The final package's license and version are computed from the licenses and versions of the database packages. The license is set to `free` if each database-providing package has a free license, and to `unfree` otherwise. The version is simply the highest version of the database-providing packages. * The final package uses `foomatic-compiledb` from the `foomatic-db-engine` package to extract all ppd files from the database packages. `patchPpdFilesHook` is used to patch most executable invocations in the ppd files so that they point to nix store paths. Finally, ppd files are gzipped to reduce storage (from about 550 MiB to 90 MiB installed). The "nonfree" version of the package, i.e. the version that is based on `foomatic-db-nonfree` in addition to `foomatic-db`, contains about 120 additional ppd files compared to the "free" version. Since the "free" version already produces about 8,700 ppd files and hydra won't build the "nonfree" version, the commit adds two package variables to `all-packages.nix`: * `foomatic-db-ppds` is based on `foomatic-db` only * `foomatic-db-ppds-withNonfreeDb` is also based on `foomaitc-db-nonfree` The package introduced by this commit is the result of combining other packages; it is not the build product of a simple source tarball. While it would also be possible to perform the ppd file generation directly in the build process of the database packages, this would yield further complexity as the `foomatic-db-nonfree` package needs to be combined with the `foomatic-db` package before ppd file extraction is possible. There is no upstream product with a name that could/should be used for the `name` attribute, the variable name, or for the filename in nixpkgs. Similar packages have different names across distributions: * https://repology.org/projects/?search=openprinting * https://repology.org/projects/?search=foomatic The name `foomatic-db-ppds` seems to be most common (albeit not really *that* common): * https://repology.org/project/foomatic-db-ppds/versions At least openSUSE splits their corresponding package into multiple "binary" packages (similar to our multi-output packages): * https://build.opensuse.org/package/binaries/Printing/OpenPrintingPPDs/openSUSE_Tumbleweed I considered something similar. However, after doing some statistics, I concluded that it's not worth the effort: The biggest dependencies (`perl` and `cups-filters`) are already present on most NixOS systems, and they cannot be "split away" easily since it cannot be done along a canonical line (e.g. printer driver). Splitting directly by dependency risks that ppd files unexpectedly "move from output to output" on package updates; disappearing ppd files can be quite annoying for package users.
This commit is contained in:
parent
156cc612ff
commit
075d112131
|
@ -69,11 +69,15 @@ stdenv.mkDerivation {
|
||||||
# searching for ppd files can find this package
|
# searching for ppd files can find this package
|
||||||
longDescription = ''
|
longDescription = ''
|
||||||
The collected knowledge about printers,
|
The collected knowledge about printers,
|
||||||
drivers, and driver options in XML files.
|
drivers, and driver options in XML files,
|
||||||
|
used by `foomatic-db-engine` to generate PPD files.
|
||||||
This is a package of PPD and Foomatic XML files
|
This is a package of PPD and Foomatic XML files
|
||||||
that may have restrictions that keep them
|
that may have restrictions that keep them
|
||||||
from being used on a variety of machines
|
from being used on a variety of machines
|
||||||
for licensing and other non-technical reasons.
|
for licensing and other non-technical reasons.
|
||||||
|
The XML files in this package enable `foomatic-db-ppds`
|
||||||
|
to create about 120 additional PPD files, for printer from
|
||||||
|
Dell, Genicom, Lexmark, Oce, Tektronix and Xerox.
|
||||||
Besides the XML files, this package contains
|
Besides the XML files, this package contains
|
||||||
about 130 PPD files, for printers from
|
about 130 PPD files, for printers from
|
||||||
Dell, Genicom, Lexmark, Oce and Xerox.
|
Dell, Genicom, Lexmark, Oce and Xerox.
|
||||||
|
|
122
pkgs/misc/cups/drivers/foomatic-db-ppds/default.nix
Normal file
122
pkgs/misc/cups/drivers/foomatic-db-ppds/default.nix
Normal file
|
@ -0,0 +1,122 @@
|
||||||
|
{ lib
|
||||||
|
, foomatic-db
|
||||||
|
, foomatic-db-nonfree
|
||||||
|
, buildEnv
|
||||||
|
, foomatic-db-engine
|
||||||
|
, stdenv
|
||||||
|
, cups-filters
|
||||||
|
, ghostscript
|
||||||
|
, netpbm
|
||||||
|
, perl
|
||||||
|
, psutils
|
||||||
|
, patchPpdFilesHook
|
||||||
|
, withNonfreeDb ? false # include foomatic-db-nonfree ppd files
|
||||||
|
}:
|
||||||
|
|
||||||
|
let
|
||||||
|
foomatic-db-packages = [ foomatic-db ] ++
|
||||||
|
lib.lists.optional withNonfreeDb foomatic-db-nonfree;
|
||||||
|
|
||||||
|
foomatic-db-combined = buildEnv {
|
||||||
|
name = "foomatic-db-combined";
|
||||||
|
paths = foomatic-db-packages;
|
||||||
|
pathsToLink = [ "/share/foomatic" ];
|
||||||
|
# `foomatic-db-combined` is a nativeBuildInput of `foomatic-db-ppds`.
|
||||||
|
# The setup hook defined here helps scripts in
|
||||||
|
# `foomatic-db-engine` to find the database.
|
||||||
|
postBuild = ''
|
||||||
|
mkdir -p "${placeholder "out"}"/{etc/cups,nix-support}
|
||||||
|
cat >> "${placeholder "out"}/nix-support/setup-hook" << eof
|
||||||
|
export FOOMATICDB="${placeholder "out"}/share/foomatic"
|
||||||
|
eof
|
||||||
|
'';
|
||||||
|
};
|
||||||
|
|
||||||
|
# the effective license is `free` if all database
|
||||||
|
# packages have free licenses, `unfree` otherwise
|
||||||
|
isFree = lib.trivial.pipe foomatic-db-packages [
|
||||||
|
(lib.lists.map (lib.attrsets.attrByPath [ "meta" "license" ] lib.licenses.unfree))
|
||||||
|
(lib.lists.all (lib.attrsets.attrByPath [ "free" ] true))
|
||||||
|
];
|
||||||
|
in
|
||||||
|
|
||||||
|
stdenv.mkDerivation {
|
||||||
|
pname = "foomatic-db-ppds";
|
||||||
|
# the effective version is simply the
|
||||||
|
# highest version of all database packages
|
||||||
|
version = lib.trivial.pipe foomatic-db-packages [
|
||||||
|
(lib.lists.map (lib.attrsets.getAttr "version"))
|
||||||
|
(lib.lists.sort lib.strings.versionOlder)
|
||||||
|
lib.lists.reverseList
|
||||||
|
lib.lists.head
|
||||||
|
];
|
||||||
|
|
||||||
|
buildInputs = [
|
||||||
|
cups-filters
|
||||||
|
ghostscript
|
||||||
|
netpbm
|
||||||
|
perl
|
||||||
|
psutils
|
||||||
|
];
|
||||||
|
|
||||||
|
nativeBuildInputs = [
|
||||||
|
foomatic-db-combined
|
||||||
|
foomatic-db-engine
|
||||||
|
patchPpdFilesHook
|
||||||
|
];
|
||||||
|
|
||||||
|
dontUnpack = true;
|
||||||
|
|
||||||
|
installPhase = ''
|
||||||
|
runHook preInstall
|
||||||
|
mkdir -p "${placeholder "out"}/share/cups/model"
|
||||||
|
foomatic-compiledb -j "$NIX_BUILD_CORES" -d "${placeholder "out"}/share/cups/model/foomatic-db-ppds"
|
||||||
|
runHook postInstall
|
||||||
|
'';
|
||||||
|
|
||||||
|
# Comments indicate the respective
|
||||||
|
# package the command is contained in.
|
||||||
|
ppdFileCommands = [
|
||||||
|
"cat" "echo" # coreutils
|
||||||
|
"foomatic-rip" # cups-filters or foomatic-filters
|
||||||
|
"gs" # ghostscript
|
||||||
|
"pnmflip" "pnmgamma" "pnmnoraw" # netpbm
|
||||||
|
"perl" # perl
|
||||||
|
"psresize" # psutils
|
||||||
|
# These commands aren't packaged yet.
|
||||||
|
# ppd files using these likely won't work.
|
||||||
|
#"c2050" "c2070" "cjet" "lm1100"
|
||||||
|
#"pbm2l2030" "pbm2lwxl" "rastertophaser6100"
|
||||||
|
];
|
||||||
|
|
||||||
|
# compress ppd files
|
||||||
|
postFixup = ''
|
||||||
|
echo 'compressing ppd files'
|
||||||
|
find -H "${placeholder "out"}/share/cups/model/foomatic-db-ppds" -type f -iname '*.ppd' -print0 \
|
||||||
|
| xargs -0r -n 64 -P "$NIX_BUILD_CORES" gzip -9n
|
||||||
|
'';
|
||||||
|
|
||||||
|
meta = {
|
||||||
|
description = "OpenPrinting ppd files";
|
||||||
|
homepage = "https://openprinting.github.io/projects/02-foomatic/";
|
||||||
|
license = if isFree then lib.licenses.free else lib.licenses.unfree;
|
||||||
|
maintainers = [ lib.maintainers.yarny ];
|
||||||
|
# list printer manufacturers here so people
|
||||||
|
# searching for ppd files can find this package
|
||||||
|
longDescription = ''
|
||||||
|
All PPD files available in
|
||||||
|
OpenPrinting's Foomatic database.
|
||||||
|
This package contains about 8,800 PPD files,
|
||||||
|
for printers from
|
||||||
|
Alps, Anitech, Apollo, Apple, Avery, Brother, Canon,
|
||||||
|
Citizen, CItoh, Compaq, DEC, Dell, Dymo-CoStar, Epson,
|
||||||
|
Fujitsu, FujiXerox, Generic, Genicom, Gestetner,
|
||||||
|
Heidelberg, Hitachi, HP, IBM, Imagen, Imagistics,
|
||||||
|
InfoPrint, Infotec, Kodak, KONICAMINOLTA, Kyocera, Lanier,
|
||||||
|
Lexmark, Minolta, MinoltaQMS, Mitsubishi, NEC, NRG, Oce,
|
||||||
|
Oki, Olivetti, Panasonic, PCPI, Pentax, QMS, Raven, Ricoh,
|
||||||
|
Samsung, Savin, Seiko, Sharp, SiPix, Sony, Star, Tally,
|
||||||
|
Tektronix, TexasInstruments, Toshiba, Xante and Xerox.
|
||||||
|
'';
|
||||||
|
};
|
||||||
|
}
|
|
@ -88,7 +88,10 @@ stdenv.mkDerivation {
|
||||||
# searching for ppd files can find this package
|
# searching for ppd files can find this package
|
||||||
longDescription = ''
|
longDescription = ''
|
||||||
The collected knowledge about printers,
|
The collected knowledge about printers,
|
||||||
drivers, and driver options in XML files.
|
drivers, and driver options in XML files,
|
||||||
|
used by `foomatic-db-engine` to generate PPD files.
|
||||||
|
PPD files generated from the XML files in this package
|
||||||
|
are contained in the package 'foomatic-db-ppds'.
|
||||||
Besides the XML files, this package contains
|
Besides the XML files, this package contains
|
||||||
about 6,600 PPD files, for printers from
|
about 6,600 PPD files, for printers from
|
||||||
Brother, Canon, Epson, Gestetner, HP, InfoPrint,
|
Brother, Canon, Epson, Gestetner, HP, InfoPrint,
|
||||||
|
|
|
@ -36322,6 +36322,8 @@ with pkgs;
|
||||||
foomatic-db = callPackage ../misc/cups/drivers/foomatic-db {};
|
foomatic-db = callPackage ../misc/cups/drivers/foomatic-db {};
|
||||||
foomatic-db-engine = callPackage ../misc/cups/drivers/foomatic-db-engine {};
|
foomatic-db-engine = callPackage ../misc/cups/drivers/foomatic-db-engine {};
|
||||||
foomatic-db-nonfree = callPackage ../misc/cups/drivers/foomatic-db-nonfree {};
|
foomatic-db-nonfree = callPackage ../misc/cups/drivers/foomatic-db-nonfree {};
|
||||||
|
foomatic-db-ppds = callPackage ../misc/cups/drivers/foomatic-db-ppds {};
|
||||||
|
foomatic-db-ppds-withNonfreeDb = callPackage ../misc/cups/drivers/foomatic-db-ppds { withNonfreeDb = true; };
|
||||||
|
|
||||||
gutenprint = callPackage ../misc/drivers/gutenprint { };
|
gutenprint = callPackage ../misc/drivers/gutenprint { };
|
||||||
|
|
||||||
|
|
Loading…
Reference in a new issue