From 1050eee2a2efdce788e43634567a105cb7d97d57 Mon Sep 17 00:00:00 2001
From: Udo Sauer <udo.sauer@bevuta.com>
Date: Sun, 6 Aug 2023 17:41:03 +0200
Subject: [PATCH] hostmux: init at 1.4.0

---
 pkgs/tools/misc/hostmux/default.nix | 54 +++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix     |  2 ++
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/tools/misc/hostmux/default.nix

diff --git a/pkgs/tools/misc/hostmux/default.nix b/pkgs/tools/misc/hostmux/default.nix
new file mode 100644
index 00000000000..27e714a5e7f
--- /dev/null
+++ b/pkgs/tools/misc/hostmux/default.nix
@@ -0,0 +1,54 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, installShellFiles
+, openssh
+, tmux
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "hostmux";
+  version = "1.4.0";
+
+  src = fetchFromGitHub {
+    owner = "hukl";
+    repo = "hostmux";
+    rev = finalAttrs.version;
+    hash = "sha256-odN7QFsU3MsWW8VabVjZH+8+AUFOUio8eF9ORv9iPEA=";
+  };
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  buildInputs = [
+    openssh
+    tmux
+  ];
+
+  postPatch = ''
+    substituteInPlace hostmux \
+      --replace "SSH_CMD=ssh" "SSH_CMD=${openssh}/bin/ssh" \
+      --replace "tmux -2" "${tmux}/bin/tmux -2" \
+      --replace "tmux s" "${tmux}/bin/tmux s"
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 hostmux $out/bin/hostmux
+    installManPage man/hostmux.1
+    installShellCompletion --zsh zsh-completion/_hostmux
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Small wrapper script for tmux to easily connect to a series of hosts via ssh and open a split pane for each of the hosts";
+    homepage = "https://github.com/hukl/hostmux";
+    license = lib.licenses.mit;
+    mainProgram = "hostmux";
+    maintainers = with lib.maintainers; [ fernsehmuell ];
+    platforms = lib.platforms.unix;
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 6f50a33754a..e753db16eba 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1790,6 +1790,8 @@ with pkgs;
 
   hexdiff = callPackage ../tools/misc/hexdiff { };
 
+  hostmux = callPackage ../tools/misc/hostmux { };
+
   httm = darwin.apple_sdk_11_0.callPackage ../tools/filesystems/httm { };
 
   inherit (callPackage ../tools/networking/ivpn/default.nix {}) ivpn ivpn-service;