deno: add some simple tests

pkgs/development/web/deno/default.nix

@@ -85,6 +85,7 @@ rustPlatform.buildRustPackage rec {
   '';
 
   passthru.updateScript = ./update/update.ts;
+  passthru.tests = callPackage ./tests { };
 
   meta = with lib; {
     homepage = "https://deno.land/";

pkgs/development/web/deno/tests/basic.ts

@@ -0,0 +1 @@
+console.log(1 + 1)

pkgs/development/web/deno/tests/default.nix

@@ -0,0 +1,68 @@
+{ deno, runCommand, lib, testers }:
+let
+  testDenoRun =
+    name:
+    { args ? ""
+    , dir ? ./. + "/${name}"
+    , file ? "index.ts"
+    , expected ? ""
+    , expectFailure ? false
+    }:
+    let
+      command = "deno run ${args} ${dir}/${file}";
+    in
+    runCommand "deno-test-${name}" { nativeBuildInputs = [ deno ]; meta.timeout = 60; } ''
+      HOME=$(mktemp -d)
+      if output=$(${command} 2>&1); then
+        if [[ $output =~ '${expected}' ]]; then
+          echo "Test '${name}' passed"
+          touch $out
+        else
+          echo -n ${lib.escapeShellArg command} >&2
+          echo " output did not match what was expected." >&2
+          echo "The expected was:" >&2
+          echo '${expected}' >&2
+          echo "The output was:" >&2
+          echo "$output" >&2
+          exit 1
+        fi
+      else
+        if [[ "${toString expectFailure}" == "1" ]]; then
+          echo "Test '${name}' failed as expected"
+          touch $out
+          exit 0
+        fi
+        echo -n ${lib.escapeShellArg command} >&2
+        echo " returned a non-zero exit code." >&2
+        echo "$output" >&2
+        exit 1
+      fi
+    '';
+in
+(lib.mapAttrs testDenoRun {
+  basic = {
+    dir = ./.;
+    file = "basic.ts";
+    expected = "2";
+  };
+  import-json = {
+    expected = "hello from JSON";
+  };
+  import-ts = {
+    expected = "hello from ts";
+  };
+  read-file = {
+    args = "--allow-read";
+    expected = "hello from a file";
+  };
+  fail-read-file = {
+    expectFailure = true;
+    dir = ./read-file;
+  };
+}) //
+{
+  version = testers.testVersion {
+    package = deno;
+    command = "deno --version";
+  };
+}

pkgs/development/web/deno/tests/import-json/data.json

@@ -0,0 +1 @@
+{ "msg": "hello from JSON" }

pkgs/development/web/deno/tests/import-json/index.ts

@@ -0,0 +1,2 @@
+import file from "./data.json" assert { type: "json" };
+console.log(file.msg);

pkgs/development/web/deno/tests/import-ts/index.ts

@@ -0,0 +1,3 @@
+import { sayHello } from "./lib.ts"
+
+sayHello("ts")

pkgs/development/web/deno/tests/import-ts/lib.ts

@@ -0,0 +1,3 @@
+export function sayHello(thing: string) {
+  console.log(`hello from ${thing}`);
+}

pkgs/development/web/deno/tests/read-file/data.txt

@@ -0,0 +1 @@
+hello from a file

pkgs/development/web/deno/tests/read-file/index.ts

@@ -0,0 +1,5 @@
+// trim 'file://' prefix
+const thisDir = Deno.mainModule.substring(7, Deno.mainModule.length);
+const getParent = (path: string) => path.substring(0, path.lastIndexOf("/"))
+const text = await Deno.readTextFile(getParent(thisDir) + "/data.txt");
+console.log(text);