diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index 1ccfba68453..0b565ed9f64 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -725,6 +725,7 @@
./services/networking/owamp.nix
./services/networking/pdnsd.nix
./services/networking/pixiecore.nix
+ ./services/networking/pleroma.nix
./services/networking/polipo.nix
./services/networking/powerdns.nix
./services/networking/pdns-recursor.nix
diff --git a/nixos/modules/services/networking/pleroma.nix b/nixos/modules/services/networking/pleroma.nix
new file mode 100644
index 00000000000..9b2bf9f6124
--- /dev/null
+++ b/nixos/modules/services/networking/pleroma.nix
@@ -0,0 +1,140 @@
+{ config, options, lib, pkgs, stdenv, ... }:
+let
+ cfg = config.services.pleroma;
+in {
+ options = {
+ services.pleroma = with lib; {
+ enable = mkEnableOption "pleroma";
+
+ package = mkOption {
+ type = types.package;
+ default = pkgs.pleroma-otp;
+ description = "Pleroma package to use.";
+ };
+
+ user = mkOption {
+ type = types.str;
+ default = "pleroma";
+ description = "User account under which pleroma runs.";
+ };
+
+ group = mkOption {
+ type = types.str;
+ default = "pleroma";
+ description = "Group account under which pleroma runs.";
+ };
+
+ stateDir = mkOption {
+ type = types.str;
+ default = "/var/lib/pleroma";
+ readOnly = true;
+ description = "Directory where the pleroma service will save the uploads and static files.";
+ };
+
+ configs = mkOption {
+ type = with types; listOf str;
+ description = ''
+ Pleroma public configuration.
+
+ This list gets appended from left to
+ right into /etc/pleroma/config.exs. Elixir evaluates its
+ configuration imperatively, meaning you can override a
+ setting by appending a new str to this NixOS option list.
+
+ DO NOT STORE ANY PLEROMA SECRET
+ HERE, use
+ services.pleroma.secretConfigFile
+ instead.
+
+ This setting is going to be stored in a file part of
+ the Nix store. The Nix store being world-readable, it's not
+ the right place to store any secret
+
+ Have a look to Pleroma section in the NixOS manual for more
+ informations.
+ '';
+ };
+
+ secretConfigFile = mkOption {
+ type = types.str;
+ default = "/var/lib/pleroma/secrets.exs";
+ description = ''
+ Path to the file containing your secret pleroma configuration.
+
+ DO NOT POINT THIS OPTION TO THE NIX
+ STORE, the store being world-readable, it'll
+ compromise all your secrets.
+ '';
+ };
+ };
+ };
+
+ config = lib.mkIf cfg.enable {
+ users = {
+ users."${cfg.user}" = {
+ description = "Pleroma user";
+ home = cfg.stateDir;
+ extraGroups = [ cfg.group ];
+ };
+ groups."${cfg.group}" = {};
+ };
+
+ environment.systemPackages = [ cfg.package ];
+
+ environment.etc."/pleroma/config.exs".text = ''
+ ${lib.concatMapStrings (x: "${x}") cfg.configs}
+
+ # The lau/tzdata library is trying to download the latest
+ # timezone database in the OTP priv directory by default.
+ # This directory being in the store, it's read-only.
+ # Setting that up to a more appropriate location.
+ config :tzdata, :data_dir, "/var/lib/pleroma/elixir_tzdata_data"
+
+ import_config "${cfg.secretConfigFile}"
+ '';
+
+ systemd.services.pleroma = {
+ description = "Pleroma social network";
+ after = [ "network-online.target" "postgresql.service" ];
+ wantedBy = [ "multi-user.target" ];
+ restartTriggers = [ config.environment.etc."/pleroma/config.exs".source ];
+ serviceConfig = {
+ User = cfg.user;
+ Group = cfg.group;
+ Type = "exec";
+ WorkingDirectory = "~";
+ StateDirectory = "pleroma pleroma/static pleroma/uploads";
+ StateDirectoryMode = "700";
+
+ # Checking the conf file is there then running the database
+ # migration before each service start, just in case there are
+ # some pending ones.
+ #
+ # It's sub-optimal as we'll always run this, even if pleroma
+ # has not been updated. But the no-op process is pretty fast.
+ # Better be safe than sorry migration-wise.
+ ExecStartPre =
+ let preScript = pkgs.writers.writeBashBin "pleromaStartPre"
+ "${cfg.package}/bin/pleroma_ctl migrate";
+ in "${preScript}/bin/pleromaStartPre";
+
+ ExecStart = "${cfg.package}/bin/pleroma start";
+ ExecStop = "${cfg.package}/bin/pleroma stop";
+ ExecReload = "${pkgs.coreutils}/bin/kill -HUP $MAINPID";
+
+ # Systemd sandboxing directives.
+ # Taken from the upstream contrib systemd service at
+ # pleroma/installation/pleroma.service
+ PrivateTmp = true;
+ ProtectHome = true;
+ ProtectSystem = "full";
+ PrivateDevices = false;
+ NoNewPrivileges = true;
+ CapabilityBoundingSet = "~CAP_SYS_ADMIN";
+ };
+ };
+
+ };
+ meta.maintainers = with lib.maintainers; [ ninjatrappeur ];
+ meta.doc = ./pleroma.xml;
+}
diff --git a/nixos/modules/services/networking/pleroma.xml b/nixos/modules/services/networking/pleroma.xml
new file mode 100644
index 00000000000..9ab0be3d947
--- /dev/null
+++ b/nixos/modules/services/networking/pleroma.xml
@@ -0,0 +1,132 @@
+
+ Pleroma
+ Pleroma is a lightweight activity pub server.
+
+ Quick Start
+ To get quickly started, you can use this sample NixOS configuration and adapt it to your use case.
+
+ {
+ security.acme = {
+ email = "root@tld";
+ acceptTerms = true;
+ certs = {
+ "social.tld.com" = {
+ webroot = "/var/www/social.tld.com";
+ email = "root@tld";
+ group = "nginx";
+ };
+ };
+ };
+ services = {
+ pleroma = {
+ enable = true;
+ secretConfigFile = "/var/lib/pleroma/secrets.exs";
+ configs = [
+ ''
+ import Config
+
+ config :pleroma, Pleroma.Web.Endpoint,
+ url: [host: "social.tld.com", scheme: "https", port: 443],
+ http: [ip: {127, 0, 0, 1}, port: 4000]
+
+ config :pleroma, :instance,
+ name: "NixOS test pleroma server",
+ email: "pleroma@social.tld.com",
+ notify_email: "pleroma@social.tld.com",
+ limit: 5000,
+ registrations_open: true
+
+ config :pleroma, :media_proxy,
+ enabled: false,
+ redirect_on_failure: true
+ #base_url: "https://cache.pleroma.social"
+
+ config :pleroma, Pleroma.Repo,
+ adapter: Ecto.Adapters.Postgres,
+ username: "pleroma",
+ password: "${test-db-passwd}",
+ database: "pleroma",
+ hostname: "localhost",
+ pool_size: 10,
+ prepare: :named,
+ parameters: [
+ plan_cache_mode: "force_custom_plan"
+ ]
+
+ config :pleroma, :database, rum_enabled: false
+ config :pleroma, :instance, static_dir: "/var/lib/pleroma/static"
+ config :pleroma, Pleroma.Uploaders.Local, uploads: "/var/lib/pleroma/uploads"
+ config :pleroma, configurable_from_database: false
+ ''
+ ];
+ };
+ postgresql = {
+ enable = true;
+ package = pkgs.postgresql_12;
+ };
+ nginx = {
+ enable = true;
+ addSSL = true;
+ sslCertificate = "/var/lib/acme/social.tld.com/fullchain.pem";
+ sslCertificateKey = "/var/lib/acme/social.tld.com/key.pem";
+ root = "/var/www/social.tld.com";
+ # ACME endpoint
+ locations."/.well-known/acme-challenge" = {
+ root = "/var/www/social.tld.com/";
+ };
+ virtualHosts."social.tld.com" = {
+ addSSL = true;
+ locations."/" = {
+ proxyPass = "http://127.0.0.1:4000";
+ extraConfig = ''
+ add_header 'Access-Control-Allow-Origin' '*' always;
+ add_header 'Access-Control-Allow-Methods' 'POST, PUT, DELETE, GET, PATCH, OPTIONS' always;
+ add_header 'Access-Control-Allow-Headers' 'Authorization, Content-Type, Idempotency-Key' always;
+ add_header 'Access-Control-Expose-Headers' 'Link, X-RateLimit-Reset, X-RateLimit-Limit, X-RateLimit-Remaining, X-Request-Id' always;
+ if ($request_method = OPTIONS) {
+ return 204;
+ }
+ add_header X-XSS-Protection "1; mode=block";
+ add_header X-Permitted-Cross-Domain-Policies none;
+ add_header X-Frame-Options DENY;
+ add_header X-Content-Type-Options nosniff;
+ add_header Referrer-Policy same-origin;
+ add_header X-Download-Options noopen;
+ proxy_http_version 1.1;
+ proxy_set_header Upgrade $http_upgrade;
+ proxy_set_header Connection "upgrade";
+ proxy_set_header Host $host;
+ client_max_body_size 16m;
+ '';
+ };
+ };
+ };
+ };
+ };
+
+ Note that you'll need to seed your database and upload your pleroma secrets to the path pointed by config.pleroma.secretConfigFile. You can find more informations about how to do that in the next section.
+
+
+ Generating the Pleroma Config and Seed the Database
+
+ Before using this service, you'll need to generate your
+server configuration and its associated database seed. The
+pleroma_ctl CLI utility can help you with that. You
+can start with pleroma_ctl instance gen --output config.exs
+--output-psql setup.psql, this will prompt you some
+questions and will generate both your config file and database initial
+migration.
+For more details about this configuration format, please have a look at the upstream documentation.
+To seed your database, you can use the setup.psql file you just generated by running
+
+ sudo -u postgres psql -f setup.psql
+
+ In regard of the pleroma service configuration you also just generated, you'll need to split it in two parts. The "public" part, which do not contain any secrets and thus can be safely stored in the Nix store and its "private" counterpart containing some secrets (database password, endpoint secret key, salts, etc.).
+
+ The public part will live in your NixOS machine configuration in the services.pleroma.configs option. However, it's up to you to upload the secret pleroma configuration to the path pointed by services.pleroma.secretConfigFile. You can do that manually or rely on a third party tool such as Morph or NixOps.
+
+