From 2930136b74c428ec9efeedec20930ca8fc8e6c2a Mon Sep 17 00:00:00 2001
From: Azat Bahawi <azat@bahawi.net>
Date: Sun, 4 Sep 2022 02:23:15 +0300
Subject: [PATCH] tbls: init at 1.56.2

Fixes: #189640
---
 pkgs/tools/misc/tbls/default.nix | 52 ++++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix  |  2 ++
 2 files changed, 54 insertions(+)
 create mode 100644 pkgs/tools/misc/tbls/default.nix

diff --git a/pkgs/tools/misc/tbls/default.nix b/pkgs/tools/misc/tbls/default.nix
new file mode 100644
index 00000000000..83e689a416f
--- /dev/null
+++ b/pkgs/tools/misc/tbls/default.nix
@@ -0,0 +1,52 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, testers
+, tbls
+}:
+
+buildGoModule rec {
+  pname = "tbls";
+  version = "1.56.2";
+
+  src = fetchFromGitHub {
+    owner = "k1LoW";
+    repo = "tbls";
+    rev = "v${version}";
+    sha256 = "sha256-fJbdZlgegC54OIAbygKO5GzNh6UAuT4OZp7KK+XJhvI=";
+  };
+
+  vendorSha256 = "sha256-pmnSeQHZEtsshldfq6D/r5pMYA5ivMWkzjOq2/WseYU=";
+
+  CGO_CFLAGS = [ "-Wno-format-security" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/k1LoW/tbls.commit=unspecified"
+    "-X github.com/k1LoW/tbls.date=unspecified"
+    "-X github.com/k1LoW/tbls.version=${src.rev}"
+    "-X github.com/k1LoW/tbls/version.Version=${src.rev}"
+  ];
+
+  preCheck = ''
+    # Remove tests that require additional services.
+    rm -f \
+       datasource/datasource_test.go \
+       drivers/*/*_test.go
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = tbls;
+    command = "tbls version";
+    version = src.rev;
+  };
+
+  meta = with lib; {
+    description = "A tool to generate documentation based on a database";
+    homepage = "https://github.com/k1LoW/tbls";
+    changelog = "https://github.com/k1LoW/tbls/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ azahi ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 246b7374677..30054c375d9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -33573,6 +33573,8 @@ with pkgs;
 
   tbe = libsForQt5.callPackage ../games/the-butterfly-effect { };
 
+  tbls = callPackage ../tools/misc/tbls { };
+
   tecnoballz = callPackage ../games/tecnoballz { };
 
   teetertorture = callPackage ../games/teetertorture { };