ftjam: init at 2.5.2

This commit is contained in:
AndersonTorres 2022-01-11 00:10:47 -03:00
parent 12b5c971bf
commit 2ebe9dede8
2 changed files with 54 additions and 0 deletions

View file

@ -0,0 +1,52 @@
{ lib
, stdenv
, fetchurl
, bison
}:
stdenv.mkDerivation rec {
pname = "ftjam";
version = "2.5.2";
src = fetchurl {
url = "https://downloads.sourceforge.net/project/freetype/${pname}/${version}/${pname}-${version}.tar.bz2";
hash = "sha256-6JdzUAqSkS3pGOn+v/q+S2vOedaa8ZRDX04DK4ptZqM=";
};
nativeBuildInputs = [
bison
];
preConfigure = ''
unset AR
'';
buildPhase = ''
runHook preBuild
make jam0
runHook postBuild
'';
installPhase = ''
runHook preInstall
./jam0 -j$NIX_BUILD_CORES -sBINDIR=$out/bin install
mkdir -p $out/doc/jam
cp *.html $out/doc/jam
runHook postInstall
'';
enableParallelBuilding = true;
meta = with lib; {
homepage = "https://freetype.org/jam/";
description = "Freetype's enhanced, backwards-compatible Jam clone";
license = licenses.free;
maintainers = with maintainers; [ AndersonTorres ];
platforms = platforms.unix;
};
}
# TODO: setup hook for Jam

View file

@ -14879,6 +14879,8 @@ with pkgs;
jam = callPackage ../development/tools/build-managers/jam { };
ftjam = callPackage ../development/tools/build-managers/jam/ftjam.nix { };
javacc = callPackage ../development/tools/parsing/javacc {
jdk = jdk8;
};