From 2ec1b3609aed22f2efe58769acdad20dfeaac05d Mon Sep 17 00:00:00 2001
From: Martin Weinelt <hexa@darmstadt.ccc.de>
Date: Thu, 12 Jan 2023 03:37:04 +0100
Subject: [PATCH] python3Packages.home-assistant-chip-core: init at 2022.12.0

---
 .../home-assistant-chip-core/default.nix      | 93 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 95 insertions(+)
 create mode 100644 pkgs/development/python-modules/home-assistant-chip-core/default.nix

diff --git a/pkgs/development/python-modules/home-assistant-chip-core/default.nix b/pkgs/development/python-modules/home-assistant-chip-core/default.nix
new file mode 100644
index 00000000000..1394eef5cbd
--- /dev/null
+++ b/pkgs/development/python-modules/home-assistant-chip-core/default.nix
@@ -0,0 +1,93 @@
+{ lib
+, stdenv
+, buildPythonPackage
+, fetchPypi
+, pythonOlder
+
+# build
+, autoPatchelfHook
+
+# runtime
+, openssl_1_1
+
+# propagates
+, coloredlogs
+, construct
+, dacite
+, rich
+, pyyaml
+, ipdb
+, deprecation
+, mobly
+, pygobject3
+}:
+
+buildPythonPackage rec {
+  pname = "home-assistant-chip-core";
+  version = "2022.12.0";
+  format = "wheel";
+
+  disabled = pythonOlder "3.7";
+
+  src = let
+    system = {
+      "aarch64-linux" = {
+        name = "aarch64";
+        hash = "sha256-oNqrvbzXeXpMG3v9RK6kppONH4n7xLVaJCEFXxVj2jE=";
+      };
+      "x86_64-linux" = {
+        name = "x86_64";
+        hash = "sha256-S5n1MUig8ZDSLgWeVmu+5qLZ4kfHQUC9qZcVfM8rPvw=";
+      };
+    }.${stdenv.system} or (throw "Unsupported system");
+  in fetchPypi {
+    pname = "home_assistant_chip_core";
+    inherit version format;
+    dist = "cp37";
+    python = "cp37";
+    abi = "abi3";
+    platform = "manylinux_2_31_${system.name}";
+    hash = system.hash;
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+  ];
+
+  buildInputs = [
+    openssl_1_1
+  ];
+
+  propagatedBuildInputs = [
+    coloredlogs
+    construct
+    dacite
+    rich
+    pyyaml
+    ipdb
+    deprecation
+    mobly
+    pygobject3
+  ];
+
+  pythonImportsCheck = [
+    "chip"
+    "chip.ble"
+    # https://github.com/project-chip/connectedhomeip/pull/24376
+    #"chip.configuration"
+    "chip.discovery"
+    "chip.native"
+    "chip.storage"
+  ];
+
+  doCheck = false; # no tests
+
+  meta = with lib; {
+    description = "Python-base APIs and tools for CHIP";
+    homepage = "https://github.com/home-assistant-libs/chip-wheels";
+    license = licenses.asl20;
+    maintainers = teams.home-assistant.members;
+    platforms = platforms.linux;
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 20cf8fcdce2..d29101025ae 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -4299,6 +4299,8 @@ self: super: with self; {
 
   home-assistant-chip-clusters = callPackage ../development/python-modules/home-assistant-chip-clusters { };
 
+  home-assistant-chip-core = callPackage ../development/python-modules/home-assistant-chip-core { };
+
   homeassistant-pyozw = callPackage ../development/python-modules/homeassistant-pyozw { };
 
   homeconnect = callPackage ../development/python-modules/homeconnect { };