lomiri.deviceinfo: init at 0.2.0 (#241265)

* lomiri.deviceinfo: init at 0.1.1

* lomiri.deviceinfo: 0.1.1 -> 0.2.0

pkgs/desktops/lomiri/default.nix

@@ -9,6 +9,7 @@ let
   in {
     #### Development tools / libraries
     cmake-extras = callPackage ./development/cmake-extras { };
+    deviceinfo = callPackage ./development/deviceinfo { };
     gmenuharness = callPackage ./development/gmenuharness { };
     lomiri-api = callPackage ./development/lomiri-api { };
   };

pkgs/desktops/lomiri/development/deviceinfo/default.nix

@@ -0,0 +1,68 @@
+{ stdenv
+, lib
+, fetchFromGitLab
+, gitUpdater
+, testers
+, cmake
+, pkg-config
+, cmake-extras
+, gtest
+, yaml-cpp
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "deviceinfo";
+  version = "0.2.0";
+
+  src = fetchFromGitLab {
+    owner = "ubports";
+    repo = "development/core/deviceinfo";
+    rev = finalAttrs.version;
+    hash = "sha256-oKuX9JbYWIjroKgA2Y+/oqPkC26DPy3e6yHFU8mmbxQ=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+    "bin"
+  ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    cmake-extras
+    yaml-cpp
+  ];
+
+  checkInputs = [
+    gtest
+  ];
+
+  cmakeFlags = [
+    "-DDISABLE_TESTS=${lib.boolToString (!finalAttrs.doCheck)}"
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  passthru = {
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+    updateScript = gitUpdater { };
+  };
+
+  meta = with lib; {
+    description = "Library to detect and configure devices";
+    homepage = "https://gitlab.com/ubports/development/core/deviceinfo";
+    license = licenses.gpl3Only;
+    maintainers = teams.lomiri.members;
+    platforms = platforms.linux;
+    mainProgram = "device-info";
+    pkgConfigModules = [
+      "deviceinfo"
+    ];
+  };
+})