From 35035a543c9ed2e3383ecfdf6b9c610e20c3223c Mon Sep 17 00:00:00 2001
From: Philipp Middendorf <middendorf@plapadoo.de>
Date: Sun, 22 Dec 2019 21:10:48 +0100
Subject: [PATCH] xow: init at 0.2

---
 nixos/modules/hardware/uinput.nix       | 19 +++++++++++++++
 nixos/modules/module-list.nix           |  2 ++
 nixos/modules/services/hardware/xow.nix | 30 +++++++++++++++++++++++
 pkgs/misc/drivers/xow/default.nix       | 32 +++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix         |  2 ++
 5 files changed, 85 insertions(+)
 create mode 100644 nixos/modules/hardware/uinput.nix
 create mode 100644 nixos/modules/services/hardware/xow.nix
 create mode 100644 pkgs/misc/drivers/xow/default.nix

diff --git a/nixos/modules/hardware/uinput.nix b/nixos/modules/hardware/uinput.nix
new file mode 100644
index 00000000000..101c12fe257
--- /dev/null
+++ b/nixos/modules/hardware/uinput.nix
@@ -0,0 +1,19 @@
+{ config, pkgs, lib, ... }:
+
+let
+  cfg = config.hardware.uinput;
+in {
+  options.hardware.uinput = {
+    enable = lib.mkEnableOption "Whether to enable uinput support";
+  };
+
+  config = lib.mkIf cfg.enable {
+    boot.kernelModules = [ "uinput" ];
+
+    users.groups.uinput = {};
+
+    services.udev.extraRules = ''
+      SUBSYSTEM=="misc", KERNEL=="uinput", MODE="0660", GROUP="uinput", OPTIONS+="static_node=uinput"
+    '';
+  };
+}
diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index c2a96c72d16..a3f68207f79 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -65,6 +65,7 @@
   ./hardware/usb-wwan.nix
   ./hardware/onlykey.nix
   ./hardware/wooting.nix
+  ./hardware/uinput.nix
   ./hardware/video/amdgpu.nix
   ./hardware/video/amdgpu-pro.nix
   ./hardware/video/ati.nix
@@ -368,6 +369,7 @@
   ./services/hardware/thermald.nix
   ./services/hardware/undervolt.nix
   ./services/hardware/vdr.nix
+  ./services/hardware/xow.nix
   ./services/logging/SystemdJournal2Gelf.nix
   ./services/logging/awstats.nix
   ./services/logging/fluentd.nix
diff --git a/nixos/modules/services/hardware/xow.nix b/nixos/modules/services/hardware/xow.nix
new file mode 100644
index 00000000000..a97dd5c870d
--- /dev/null
+++ b/nixos/modules/services/hardware/xow.nix
@@ -0,0 +1,30 @@
+{ config, pkgs, lib, ... }:
+
+let
+  cfg = config.services.hardware.xow;
+in {
+  options.services.hardware.xow = {
+    enable = lib.mkEnableOption "Whether to enable xow or not.";
+  };
+
+  config = lib.mkIf cfg.enable {
+    hardware.uinput.enable = true;
+
+    users.users.xow = {
+      group = "uinput";
+      isSystemUser = true;
+    };
+
+    systemd.services.xow = {
+      wantedBy = [ "multi-user.target" ];
+      description = "Xbox One Wireless Dongle Driver";
+      after = [ "systemd-udev-settle.service" ];
+      serviceConfig = {
+        ExecStart = ''
+          ${pkgs.xow}/bin/xow
+        '';
+        User = "xow";
+      };
+    };
+  };
+}
diff --git a/pkgs/misc/drivers/xow/default.nix b/pkgs/misc/drivers/xow/default.nix
new file mode 100644
index 00000000000..5ca3f235fcc
--- /dev/null
+++ b/pkgs/misc/drivers/xow/default.nix
@@ -0,0 +1,32 @@
+{ stdenv, fetchFromGitHub, libusb, gitMinimal }:
+
+stdenv.mkDerivation rec {
+  pname = "xow";
+  version = "0.2";
+
+  src = fetchFromGitHub {
+    owner = "medusalix";
+    repo = "xow";
+    rev = "v${version}";
+    sha256 = "03ajal91xi52svzy621aa4jcdf0vj4pqd52kljam0wryrlmcpbr3";
+  };
+
+  makeFlags = [ "BUILD=RELEASE" "VERSION=${version}" ];
+  enableParallelBuilding = true;
+  buildInputs = [ libusb ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp xow $out/bin
+    runHook postInstall
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://github.com/medusalix/xow";
+    description = "Linux driver for the Xbox One wireless dongle";
+    license = licenses.gpl2Plus;
+    maintainers = [ maintainers.pmiddend ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index ef0d40f91b1..a6427ccbe98 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -26011,6 +26011,8 @@ in
 
   xboxdrv = callPackage ../misc/drivers/xboxdrv { };
 
+  xow = callPackage ../misc/drivers/xow { };
+
   xbps = callPackage ../tools/package-management/xbps { };
 
   xcftools = callPackage ../tools/graphics/xcftools { };