From 38bbcb5f42235ac3175595757f85621d0fdf9498 Mon Sep 17 00:00:00 2001
From: Euan Kemp <euank@euank.com>
Date: Fri, 23 Dec 2022 05:00:40 +0000
Subject: [PATCH] rcodesign: init at 0.22.0

---
 pkgs/development/tools/rcodesign/default.nix | 49 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  2 +
 2 files changed, 51 insertions(+)
 create mode 100644 pkgs/development/tools/rcodesign/default.nix

diff --git a/pkgs/development/tools/rcodesign/default.nix b/pkgs/development/tools/rcodesign/default.nix
new file mode 100644
index 00000000000..34227dfa705
--- /dev/null
+++ b/pkgs/development/tools/rcodesign/default.nix
@@ -0,0 +1,49 @@
+{ lib
+, stdenv
+, rustPlatform
+, fetchFromGitHub
+, darwin
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rcodesign";
+  version = "0.22.0";
+
+  src = fetchFromGitHub {
+    owner = "indygreg";
+    repo = "apple-platform-rs";
+    rev = "apple-codesign/${version}";
+    hash = "sha256-ndbDBGtTOfHHUquKrETe4a+hB5Za9samlnXwVGVvWy4=";
+  };
+
+  cargoHash = "sha256-cpQBdxTw/ge4VtzjdL2a2xgSeCT22fMIjuKu5UEedhI=";
+
+  buildInputs = lib.optionals stdenv.isDarwin [
+    darwin.apple_sdk_11_0.frameworks.Security
+  ];
+
+  cargoBuildFlags = [
+    # Only build the binary we want
+    "--bin"
+    "rcodesign"
+  ];
+
+  checkFlags = [
+    # Does network IO
+    "--skip=ticket_lookup::test::lookup_ticket"
+  ];
+
+  meta = with lib; {
+    description = "A cross-platform CLI interface to interact with Apple code signing.";
+    longDescription = ''
+      rcodesign provides various commands to interact with Apple signing,
+      including signing and notarizing binaries, generating signing
+      certificates, and verifying existing signed binaries.
+
+      For more information, refer to the [documentation](https://gregoryszorc.com/docs/apple-codesign/stable/apple_codesign_rcodesign.html).
+    '';
+    homepage = "https://github.com/indygreg/apple-platform-rs";
+    license = licenses.mpl20;
+    maintainers = with maintainers; [ euank ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index aed4f4b7547..89b5c780d37 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -17943,6 +17943,8 @@ with pkgs;
 
   hammer = callPackage ../development/tools/parsing/hammer { };
 
+  rcodesign = darwin.apple_sdk_11_0.callPackage ../development/tools/rcodesign {};
+
   rdocker = callPackage ../development/tools/rdocker { };
 
   redis-dump = callPackage ../development/tools/redis-dump { };