From 3bc6ed6e70901fa548fcbec72656fc0cd605ad4c Mon Sep 17 00:00:00 2001
From: Tobias Markus <tobias@miglix.eu>
Date: Fri, 10 Feb 2023 15:10:44 +0100
Subject: [PATCH] cctag: init at 1.0.3

---
 .../cctag/cmake-install-include-dir.patch     | 11 ++++
 pkgs/development/libraries/cctag/default.nix  | 66 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  4 ++
 3 files changed, 81 insertions(+)
 create mode 100644 pkgs/development/libraries/cctag/cmake-install-include-dir.patch
 create mode 100644 pkgs/development/libraries/cctag/default.nix

diff --git a/pkgs/development/libraries/cctag/cmake-install-include-dir.patch b/pkgs/development/libraries/cctag/cmake-install-include-dir.patch
new file mode 100644
index 00000000000..ae708e55d3e
--- /dev/null
+++ b/pkgs/development/libraries/cctag/cmake-install-include-dir.patch
@@ -0,0 +1,11 @@
+--- a/src/CMakeLists.txt
++++ b/src/CMakeLists.txt
+@@ -209,7 +209,7 @@
+   target_include_directories(CCTag
+                            PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}>"
+                                   "$<BUILD_INTERFACE:${generated_dir}>"
+-                                  "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>"
++                                  "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
+                            PUBLIC ${Boost_INCLUDE_DIRS} ${OpenCV_INCLUDE_DIRS})
+ 
+   # just for testing
diff --git a/pkgs/development/libraries/cctag/default.nix b/pkgs/development/libraries/cctag/default.nix
new file mode 100644
index 00000000000..706d2becbef
--- /dev/null
+++ b/pkgs/development/libraries/cctag/default.nix
@@ -0,0 +1,66 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+
+, cmake
+, boost
+, eigen
+, opencv
+, tbb
+
+, avx2Support ? stdenv.hostPlatform.avx2Support
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cctag";
+  version = "1.0.3";
+
+  outputs = [ "lib" "dev" "out" ];
+
+  src = fetchFromGitHub {
+    owner = "alicevision";
+    repo = "CCTag";
+    rev = "v${version}";
+    hash = "sha256-foB+e7BCuUucyhN8FsI6BIT3/fsNLTjY6QmjkMWZu6A=";
+  };
+
+  cmakeFlags = [
+    # Feel free to create a PR to add CUDA support
+    "-DCCTAG_WITH_CUDA=OFF"
+
+    "-DCCTAG_ENABLE_SIMD_AVX2=${if avx2Support then "ON" else "OFF"}"
+
+    "-DCCTAG_BUILD_TESTS=${if doCheck then "ON" else "OFF"}"
+    "-DCCTAG_BUILD_APPS=OFF"
+  ];
+
+  patches = [
+    ./cmake-install-include-dir.patch
+  ];
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  propagatedBuildInputs = [
+    tbb
+  ];
+
+  buildInputs = [
+    boost
+    eigen
+    opencv
+  ];
+
+  # Tests are broken on Darwin (linking issue)
+  doCheck = !stdenv.isDarwin;
+
+  meta = with lib; {
+    description = "Detection of CCTag markers made up of concentric circles";
+    homepage = "https://cctag.readthedocs.io";
+    downloadPage = "https://github.com/alicevision/CCTag";
+    license = licenses.mpl20;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ tmarkus ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 22049bd8762..e5da01e43db 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -19447,6 +19447,10 @@ with pkgs;
 
   ccrtp = callPackage ../development/libraries/ccrtp { };
 
+  cctag = callPackage ../development/libraries/cctag {
+    tbb = tbb_2021_8;
+  };
+
   cctz = callPackage ../development/libraries/cctz {
     inherit (darwin.apple_sdk.frameworks) Foundation;
   };