diff --git a/nixos/modules/hardware/video/uvcvideo/default.nix b/nixos/modules/hardware/video/uvcvideo/default.nix
new file mode 100644
index 00000000000..7e3e94fdf2b
--- /dev/null
+++ b/nixos/modules/hardware/video/uvcvideo/default.nix
@@ -0,0 +1,64 @@
+
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+ cfg = config.services.uvcvideo;
+
+ uvcdynctrl-udev-rules = packages: pkgs.callPackage ./uvcdynctrl-udev-rules.nix {
+ drivers = packages;
+ udevDebug = false;
+ };
+
+in
+
+{
+
+ options = {
+ services.uvcvideo.dynctrl = {
+
+ enable = mkOption {
+ type = types.bool;
+ default = false;
+ description = ''
+ Whether to enable uvcvideo dynamic controls.
+
+ Note that enabling this brings the uvcdynctrl tool
+ into your environement and register all dynamic controls from
+ specified packages to the uvcvideo driver.
+ '';
+ };
+
+ packages = mkOption {
+ type = types.listOf types.path;
+ example = literalExample "[ pkgs.tiscamera ]";
+ description = ''
+ List of packages containing uvcvideo dynamic controls
+ rules. All files found in
+ pkg/share/uvcdynctrl/data
+ will be included.
+
+ Note that these will serve as input to the libwebcam
+ package which through its own udev rule will register
+ the dynamic controls from specified packages to the uvcvideo
+ driver.
+ '';
+ apply = map getBin;
+ };
+ };
+ };
+
+ config = mkIf cfg.dynctrl.enable {
+
+ services.udev.packages = [
+ (uvcdynctrl-udev-rules cfg.dynctrl.packages)
+ ];
+
+ environment.systemPackages = [
+ pkgs.libwebcam
+ ];
+
+ };
+}
diff --git a/nixos/modules/hardware/video/uvcvideo/uvcdynctrl-udev-rules.nix b/nixos/modules/hardware/video/uvcvideo/uvcdynctrl-udev-rules.nix
new file mode 100644
index 00000000000..832e6196612
--- /dev/null
+++ b/nixos/modules/hardware/video/uvcvideo/uvcdynctrl-udev-rules.nix
@@ -0,0 +1,46 @@
+{ lib
+, stdenv
+, buildEnv
+, libwebcam
+, makeWrapper
+, runCommand
+, drivers ? []
+, udevDebug ? false
+}:
+
+let
+ version = "0.0.0";
+
+ dataPath = buildEnv {
+ name = "uvcdynctrl-with-drivers-data-path";
+ paths = drivers ++ [ libwebcam ];
+ pathsToLink = [ "/share/uvcdynctrl/data" ];
+ ignoreCollisions = false;
+ };
+
+ dataDir = "${dataPath}/share/uvcdynctrl/data";
+ udevDebugVarValue = if udevDebug then "1" else "0";
+in
+
+runCommand "uvcdynctrl-udev-rules-${version}"
+{
+ inherit dataPath;
+ buildInputs = [
+ makeWrapper
+ libwebcam
+ ];
+ dontPatchELF = true;
+ dontStrip = true;
+}
+''
+ mkdir -p "$out/lib/udev"
+ makeWrapper "${libwebcam}/lib/udev/uvcdynctrl" "$out/lib/udev/uvcdynctrl" \
+ --set NIX_UVCDYNCTRL_DATA_DIR "${dataDir}" \
+ --set NIX_UVCDYNCTRL_UDEV_DEBUG "${udevDebugVarValue}"
+
+ mkdir -p "$out/lib/udev/rules.d"
+ cat "${libwebcam}/lib/udev/rules.d/80-uvcdynctrl.rules" | \
+ sed -r "s#RUN\+\=\"([^\"]+)\"#RUN\+\=\"$out/lib/udev/uvcdynctrl\"#g" > \
+ "$out/lib/udev/rules.d/80-uvcdynctrl.rules"
+''
+
diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index da4c21296ff..e692fc0fb7d 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -50,6 +50,7 @@
./hardware/video/bumblebee.nix
./hardware/video/displaylink.nix
./hardware/video/nvidia.nix
+ ./hardware/video/uvcvideo/default.nix
./hardware/video/webcam/facetimehd.nix
./i18n/input-method/default.nix
./i18n/input-method/fcitx.nix