From 4908631f89d29ba0d741d4d119f6a76a46c0adb3 Mon Sep 17 00:00:00 2001
From: GetPsyched <priyanshutr@proton.me>
Date: Mon, 12 Jun 2023 00:44:18 +0400
Subject: [PATCH] atlauncher: init at 3.4.28.1

---
 pkgs/games/atlauncher/default.nix | 57 +++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix   |  2 ++
 2 files changed, 59 insertions(+)
 create mode 100644 pkgs/games/atlauncher/default.nix

diff --git a/pkgs/games/atlauncher/default.nix b/pkgs/games/atlauncher/default.nix
new file mode 100644
index 00000000000..913b4faffb8
--- /dev/null
+++ b/pkgs/games/atlauncher/default.nix
@@ -0,0 +1,57 @@
+{ copyDesktopItems, fetchurl, jre, lib, makeDesktopItem, makeWrapper, stdenv, steam-run, withSteamRun ? true, writeShellScript }:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "atlauncher";
+  version = "3.4.28.1";
+
+  src = fetchurl {
+    url = "https://github.com/ATLauncher/ATLauncher/releases/download/v${finalAttrs.version}/ATLauncher-${finalAttrs.version}.jar";
+    hash = "sha256-IIwDMazxUMQ7nGQk/4VEZicgCmCR4oR8UYtO36pCEq4=";
+  };
+
+  dontUnpack = true;
+
+  buildInputs = [ ];
+  nativeBuildInputs = [ copyDesktopItems makeWrapper ];
+
+  installPhase =
+    let
+      # hack to use steam-run along with the exec
+      steamrun = writeShellScript "steamrun" ''
+        shift
+        exec ${steam-run}/bin/steam-run "''$@"
+      '';
+    in
+    ''
+      runHook preInstall
+      mkdir -p $out/bin
+      makeWrapper ${jre}/bin/java $out/bin/atlauncher \
+        --add-flags "-jar $src --working-dir=\$HOME/.atlauncher" \
+        --suffix LD_LIBRARY_PATH : "${lib.makeLibraryPath finalAttrs.buildInputs}" ${
+            lib.strings.optionalString withSteamRun ''--run "${steamrun} \\"''
+          }
+      runHook postInstall
+    '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = finalAttrs.pname;
+      exec = finalAttrs.pname;
+      icon = fetchurl {
+        url = "https://avatars.githubusercontent.com/u/7068667";
+        hash = "sha256-YmEkxf4rZxN3jhiib0UtdUDDcn9lw7IMbiEucBL7b9o=";
+      };
+      desktopName = "ATLauncher";
+      categories = [ "Game" ];
+    })
+  ];
+
+  meta = with lib; {
+    description = "A simple and easy to use Minecraft launcher which contains many different modpacks for you to choose from and play";
+    downloadPage = "https://atlauncher.com/downloads";
+    homepage = "https://atlauncher.com/";
+    license = licenses.gpl3;
+    maintainers = [ maintainers.getpsyched ];
+    platforms = platforms.all;
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 1ae20d02648..098e93f8510 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -36213,6 +36213,8 @@ with pkgs;
 
   antsimulator = callPackage ../games/antsimulator { };
 
+  atlauncher = callPackage ../games/atlauncher { };
+
   augustus = callPackage ../games/augustus { };
 
   ballerburg = callPackage ../games/ballerburg { } ;