gssdp_1_6: init at 1.5.2

https://gitlab.gnome.org/GNOME/gssdp/-/compare/gssdp-1.4.0.1...gssdp-1.5.2

Changelog-Reviewed-By: Jan Tojnar <jtojnar@gmail.com>

pkgs/development/libraries/gssdp/1.6.nix

@@ -0,0 +1,83 @@
+{ stdenv
+, lib
+, fetchurl
+, meson
+, ninja
+, pkg-config
+, gobject-introspection
+, vala
+, gi-docgen
+, python3
+, libsoup_3
+, glib
+, gnome
+, gssdp-tools
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gssdp";
+  version = "1.5.2";
+
+  outputs = [ "out" "dev" ]
+    ++ lib.optionals (stdenv.buildPlatform == stdenv.hostPlatform) [ "devdoc" ];
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/gssdp/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
+    sha256 = "60CscnTY3AbRonW8iBMlfZlg54qKbZrPPgF6oWoXFh4=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection
+    vala
+    gi-docgen
+    python3
+  ];
+
+  buildInputs = [
+    libsoup_3
+  ];
+
+  propagatedBuildInputs = [
+    glib
+  ];
+
+  mesonFlags = [
+    "-Dgtk_doc=${lib.boolToString (stdenv.buildPlatform == stdenv.hostPlatform)}"
+    "-Dsniffer=false"
+    "-Dintrospection=${lib.boolToString (stdenv.buildPlatform == stdenv.hostPlatform)}"
+  ];
+
+  doCheck = true;
+
+  postFixup = lib.optionalString (stdenv.buildPlatform == stdenv.hostPlatform) ''
+    # Move developer documentation to devdoc output.
+    # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
+    find -L "$out/share/doc" -type f -regex '.*\.devhelp2?' -print0 \
+      | while IFS= read -r -d ''' file; do
+        moveToOutput "$(dirname "''${file/"$out/"/}")" "$devdoc"
+    done
+  '';
+
+  passthru = {
+    updateScript = gnome.updateScript {
+      attrPath = "gssdp_1_6";
+      packageName = pname;
+    };
+
+    tests = {
+      inherit gssdp-tools;
+    };
+  };
+
+  meta = with lib; {
+    broken = stdenv.isDarwin;
+    description = "GObject-based API for handling resource discovery and announcement over SSDP";
+    homepage = "http://www.gupnp.org/";
+    license = licenses.lgpl2Plus;
+    maintainers = teams.gnome.members;
+    platforms = platforms.all;
+  };
+}

pkgs/development/libraries/gssdp/default.nix

@@ -64,6 +64,7 @@ stdenv.mkDerivation rec {
   passthru = {
     updateScript = gnome.updateScript {
       packageName = pname;
+      freeze = true;
     };
 
     tests = {

pkgs/development/libraries/gssdp/standalone-tools.patch

@@ -22,9 +22,9 @@ index 40eb8e3..5db545b 100644
 +project('gssdp-tools', 'c', version: '@version@')
 +gnome = import('gnome')
 +
-+gssdp = dependency('gssdp-1.2')
++gssdp = dependency('gssdp-1.6')
 +gtk = dependency('gtk4', version : '>= 4')
-+libsoup = dependency('libsoup-2.4', version : '>= 2.26.1')
++libsoup = dependency('libsoup-3.0', version : '>= 2.99.0')
 +
  resource = gnome.compile_resources(
      'org.gupnp.GSSDP.DeviceSniffer',

pkgs/development/libraries/gssdp/tools.nix

@@ -5,14 +5,14 @@
 , ninja
 , pkg-config
 , wrapGAppsHook4
-, gssdp
+, gssdp_1_6
 , gtk4
-, libsoup
+, libsoup_3
 }:
 
 stdenv.mkDerivation rec {
   pname = "gssdp-tools";
-  inherit (gssdp) version src;
+  inherit (gssdp_1_6) version src;
 
   patches = [
     # Allow building tools separately from the library.
@@ -31,9 +31,9 @@ stdenv.mkDerivation rec {
   ];
 
   buildInputs = [
-    gssdp
+    gssdp_1_6
     gtk4
-    libsoup
+    libsoup_3
   ];
 
   preConfigure = ''
@@ -44,7 +44,7 @@ stdenv.mkDerivation rec {
     description = "Device Sniffer tool based on GSSDP framework";
     homepage = "http://www.gupnp.org/";
     license = licenses.lgpl2Plus;
-    maintainers = gssdp.meta.maintainers;
+    maintainers = gssdp_1_6.meta.maintainers;
     platforms = platforms.all;
   };
 }

pkgs/top-level/all-packages.nix

@@ -7426,6 +7426,8 @@ with pkgs;
 
   gssdp = callPackage ../development/libraries/gssdp { };
 
+  gssdp_1_6 = callPackage ../development/libraries/gssdp/1.6.nix { };
+
   gssdp-tools = callPackage ../development/libraries/gssdp/tools.nix { };
 
   grype = callPackage ../tools/security/grype { };