From 744ddf36185d85719c5f50f7d1d9e4a46908e82c Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Ga=C3=ABl=20Reyrol?= <me@gaelreyrol.dev>
Date: Thu, 29 Jun 2023 23:16:14 +0200
Subject: [PATCH] owntracks-recorder: init at 0.9.3

---
 pkgs/servers/owntracks-recorder/default.nix | 82 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  2 +
 2 files changed, 84 insertions(+)
 create mode 100644 pkgs/servers/owntracks-recorder/default.nix

diff --git a/pkgs/servers/owntracks-recorder/default.nix b/pkgs/servers/owntracks-recorder/default.nix
new file mode 100644
index 00000000000..47b3b696fd4
--- /dev/null
+++ b/pkgs/servers/owntracks-recorder/default.nix
@@ -0,0 +1,82 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, pkg-config
+, mosquitto
+, curl
+, openssl
+, lmdb
+, lua
+, libsodium
+, libuuid
+, libconfig
+, testers
+, owntracks-recorder
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "owntracks-recorder";
+  version = "0.9.3";
+
+  src = fetchFromGitHub {
+    owner = "owntracks";
+    repo = "recorder";
+    rev = finalAttrs.version;
+    hash = "sha256-w0wk69hERGz6fs6uXBYiomcVlQeeTGCfTICu2q7ryNg=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    (lib.getDev curl)
+    (lib.getLib libconfig)
+    (lib.getDev openssl)
+    (lib.getDev lmdb)
+    (lib.getDev mosquitto)
+    (lib.getDev libuuid)
+    (lib.getDev lua)
+    (lib.getDev libsodium)
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    cp config.mk.in config.mk
+
+    substituteInPlace config.mk \
+      --replace "INSTALLDIR = /usr/local" "INSTALLDIR = $out" \
+      --replace "WITH_LUA ?= no" "WITH_LUA ?= yes" \
+      --replace "WITH_ENCRYPT ?= no" "WITH_ENCRYPT ?= yes"
+
+    runHook postConfigure
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+
+    install -m 0755 ot-recorder $out/bin
+    install -m 0755 ocat $out/bin
+
+    runHook postInstall
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = owntracks-recorder;
+    command = "ocat --version";
+    version = finalAttrs.version;
+  };
+
+  meta = with lib; {
+    description = "Store and access data published by OwnTracks apps";
+    homepage = "https://github.com/owntracks/recorder";
+    changelog = "https://github.com/owntracks/recorder/blob/master/Changelog";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ gaelreyrol ];
+    mainProgram = "ot-recorder";
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 21b83d86d6d..c44703a6a89 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -11119,6 +11119,8 @@ with pkgs;
 
   owncast = callPackage ../servers/owncast { };
 
+  owntracks-recorder = callPackage ../servers/owntracks-recorder { };
+
   update-dotdee = with python3Packages; toPythonApplication update-dotdee;
 
   update-nix-fetchgit = haskell.lib.compose.justStaticExecutables haskellPackages.update-nix-fetchgit;