From 823107038bdc66d6868b4469fb19573ef8cd7c17 Mon Sep 17 00:00:00 2001
From: Vincent Laporte <Vincent.Laporte@gmail.com>
Date: Fri, 22 Mar 2019 09:10:55 +0000
Subject: [PATCH] coqPackages.coqhammer: init at 1.1

CoqHammer is a general-purpose automated reasoning hammer tool for Coq.

Homepage: http://cl-informatik.uibk.ac.at/cek/coqhammer/
---
 .../coq-modules/coqhammer/default.nix         | 55 +++++++++++++++++++
 pkgs/top-level/coq-packages.nix               |  1 +
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/development/coq-modules/coqhammer/default.nix

diff --git a/pkgs/development/coq-modules/coqhammer/default.nix b/pkgs/development/coq-modules/coqhammer/default.nix
new file mode 100644
index 00000000000..28c651f9b16
--- /dev/null
+++ b/pkgs/development/coq-modules/coqhammer/default.nix
@@ -0,0 +1,55 @@
+{ stdenv, fetchFromGitHub, coq }:
+
+let
+  params = {
+    "8.8" = {
+      sha256 = "0ms086wp4jmrzyglb8wymchzyflflk01nsfsk4r6qv8rrx81nx9h";
+    };
+    "8.9" = {
+      sha256 = "0hmqwsry8ldg4g4hhwg4b84dgzibpdrg1wwsajhlyqfx3fb3n3b5";
+    };
+  };
+  param = params."${coq.coq-version}";
+in
+
+stdenv.mkDerivation rec {
+  version = "1.1";
+  name = "coq${coq.coq-version}-coqhammer-${version}";
+
+  src = fetchFromGitHub {
+    owner = "lukaszcz";
+    repo = "coqhammer";
+    rev = "v${version}-coq${coq.coq-version}";
+    inherit (param) sha256;
+  };
+
+  postPatch = ''
+    substituteInPlace Makefile.coq.local --replace \
+      '$(if $(COQBIN),$(COQBIN),`coqc -where | xargs dirname | xargs dirname`/bin/)' \
+      '$(out)/bin/'
+    substituteInPlace Makefile.coq.local --replace 'g++' 'c++' --replace 'gcc' 'cc'
+  '';
+
+  buildInputs = [ coq ] ++ (with coq.ocamlPackages; [
+    ocaml findlib camlp5
+  ]);
+
+  preInstall = ''
+    mkdir -p $out/bin
+  '';
+
+  installFlags = [ "COQLIB=$(out)/lib/coq/${coq.coq-version}/" ];
+
+  meta = {
+    homepage = "http://cl-informatik.uibk.ac.at/cek/coqhammer/";
+    description = "Automation for Dependent Type Theory";
+    license = stdenv.lib.licenses.lgpl21;
+    inherit (coq.meta) platforms;
+    maintainers = [ stdenv.lib.maintainers.vbgl ];
+  };
+
+  passthru = {
+    compatibleCoqVersions = v: builtins.hasAttr v params;
+  };
+
+}
diff --git a/pkgs/top-level/coq-packages.nix b/pkgs/top-level/coq-packages.nix
index 5f55d88cb77..f08f2eacc23 100644
--- a/pkgs/top-level/coq-packages.nix
+++ b/pkgs/top-level/coq-packages.nix
@@ -19,6 +19,7 @@ let
       coq-ext-lib = callPackage ../development/coq-modules/coq-ext-lib {};
       coq-extensible-records = callPackage ../development/coq-modules/coq-extensible-records {};
       coq-haskell = callPackage ../development/coq-modules/coq-haskell { };
+      coqhammer = callPackage ../development/coq-modules/coqhammer {};
       coqprime = callPackage ../development/coq-modules/coqprime {};
       coquelicot = callPackage ../development/coq-modules/coquelicot {};
       corn = callPackage ../development/coq-modules/corn {};