From 9a75b8d585f9f0e818cd45dff3729c9b5b00db4f Mon Sep 17 00:00:00 2001
From: Sebastian Zivota <sebastian.zivota@mailbox.org>
Date: Wed, 3 Mar 2021 00:07:54 +0100
Subject: [PATCH] kakoune.cr: init at unstable-2021-11-12

Co-authored-by: Sebastian Zivota <sebastian.zivota@mailbox.org>
---
 pkgs/tools/misc/kakoune-cr/default.nix | 49 ++++++++++++++++++++++++++
 pkgs/tools/misc/kakoune-cr/shard.lock  | 10 ++++++
 pkgs/tools/misc/kakoune-cr/shards.nix  | 14 ++++++++
 pkgs/top-level/all-packages.nix        |  2 ++
 4 files changed, 75 insertions(+)
 create mode 100644 pkgs/tools/misc/kakoune-cr/default.nix
 create mode 100644 pkgs/tools/misc/kakoune-cr/shard.lock
 create mode 100644 pkgs/tools/misc/kakoune-cr/shards.nix

diff --git a/pkgs/tools/misc/kakoune-cr/default.nix b/pkgs/tools/misc/kakoune-cr/default.nix
new file mode 100644
index 00000000000..78504c1fc79
--- /dev/null
+++ b/pkgs/tools/misc/kakoune-cr/default.nix
@@ -0,0 +1,49 @@
+{ lib, crystal, fetchFromGitHub, fetchurl, jq }:
+let
+  icon = fetchurl {
+    url = "https://github.com/mawww/kakoune/raw/master/doc/kakoune_logo.svg";
+    hash = "sha256-JxhIEmjiGrisaarA1sX1AfzNjHNIm9xjyPs/nG1uL/U=";
+  };
+in
+crystal.buildCrystalPackage rec {
+  pname = "kakoune.cr";
+  version = "unstable-2021-11-12";
+
+  src = fetchFromGitHub {
+    owner = "alexherbo2";
+    repo = "kakoune.cr";
+    rev = "43d4276e1d173839f335ff60f205b89705892e00";
+    hash = "sha256-xFrxbnZl/49vGKdkESPa6LpK0ckq4Jv5GNLL/G0qA1w=";
+  };
+
+  propagatedUserEnvPkgs = [ jq ];
+
+  format = "shards";
+  shardsFile = ./shards.nix;
+  lockFile = ./shard.lock;
+
+  preConfigure = ''
+    substituteInPlace src/kakoune/version.cr --replace \
+      '`git describe --tags --always`' \
+      '"${version}"'
+  '';
+
+  postInstall = ''
+    install -Dm555 share/kcr/commands/*/kcr-* -t $out/bin
+    install -Dm444 share/kcr/applications/kcr.desktop -t $out/share/applications
+    install -Dm444 ${icon} $out/share/icons/hicolor/scalable/apps/kcr.svg
+    cp -r share/kcr $out/share/
+  '';
+
+  installCheckPhase = ''
+    $out/bin/kcr --help
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/alexherbo2/kakoune.cr";
+    description = "A command-line tool for Kakoune";
+    license = licenses.unlicense;
+    maintainers = with maintainers; [ malvo ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/pkgs/tools/misc/kakoune-cr/shard.lock b/pkgs/tools/misc/kakoune-cr/shard.lock
new file mode 100644
index 00000000000..79981b8460d
--- /dev/null
+++ b/pkgs/tools/misc/kakoune-cr/shard.lock
@@ -0,0 +1,10 @@
+version: 2.0
+shards:
+  fifo:
+    git: https://github.com/alexherbo2/fifo.cr.git
+    version: 0.1.0+git.commit.37a2cc2718af0f8a1c50071106d7a5ca3a0d3da2
+
+  rsub:
+    git: https://github.com/alexherbo2/rsub.cr.git
+    version: 0.1.0+git.commit.43c6b9836ee281328bccfdf8c669bab26448e3b3
+
diff --git a/pkgs/tools/misc/kakoune-cr/shards.nix b/pkgs/tools/misc/kakoune-cr/shards.nix
new file mode 100644
index 00000000000..b4160f403c7
--- /dev/null
+++ b/pkgs/tools/misc/kakoune-cr/shards.nix
@@ -0,0 +1,14 @@
+{
+  fifo = {
+    owner = "alexherbo2";
+    repo = "fifo.cr";
+    rev = "37a2cc2718af0f8a1c50071106d7a5ca3a0d3da2";
+    sha256 = "0syh2819dzsfb562z645sajfh7xplhh3mxdachjnzlsdfqkxw85r";
+  };
+  rsub = {
+    owner = "alexherbo2";
+    repo = "rsub.cr";
+    rev = "43c6b9836ee281328bccfdf8c669bab26448e3b3";
+    sha256 = "144p83y3d02jy4gapify53x3i4i51yva6ajbvgi8rx0zj2ajgr0d";
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f5d5eb740ad..a298c48a360 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -6996,6 +6996,8 @@ with pkgs;
     inherit (darwin.apple_sdk.frameworks) Security SystemConfiguration;
   };
 
+  kakoune-cr = callPackage ../tools/misc/kakoune-cr { };
+
   kbdd = callPackage ../applications/window-managers/kbdd { };
 
   kbs2 = callPackage ../tools/security/kbs2 {