Merge pull request #206328 from atorres1985-contrib/katriawm

katriawm: init at 21.09

nixos/modules/services/x11/window-managers/katriawm.nix

@@ -0,0 +1,27 @@
+{ config, lib, pkgs, ... }:
+
+let
+  inherit (lib) mdDoc mkEnableOption mkIf mkPackageOption singleton;
+  cfg = config.services.xserver.windowManager.katriawm;
+in
+{
+  ###### interface
+  options = {
+    services.xserver.windowManager.katriawm = {
+      enable = mkEnableOption (mdDoc "katriawm");
+      package = mkPackageOption pkgs "katriawm" {};
+    };
+  };
+
+  ###### implementation
+  config = mkIf cfg.enable {
+    services.xserver.windowManager.session = singleton {
+      name = "katriawm";
+      start = ''
+        ${cfg.package}/bin/katriawm &
+        waitPID=$!
+      '';
+    };
+    environment.systemPackages = [ cfg.package ];
+  };
+}

pkgs/applications/window-managers/katriawm/default.nix

@@ -0,0 +1,43 @@
+{ lib
+, stdenv
+, fetchzip
+, libX11
+, libXft
+, libXrandr
+, pkg-config
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "katriawm";
+  version = "21.09";
+
+  src = fetchzip {
+    name = finalAttrs.pname + "-" + finalAttrs.version;
+    url = "https://www.uninformativ.de/git/katriawm/archives/katriawm-v${finalAttrs.version}.tar.gz";
+    hash = "sha256-xt0sWEwTcCs5cwoB3wVbYcyAKL0jx7KyeCefEBVFhH8=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    libX11
+    libXft
+    libXrandr
+  ];
+
+  preBuild = ''
+    cd src
+  '';
+
+  installFlags = [ "prefix=$(out)" ];
+
+  meta = with lib; {
+    homepage = "https://www.uninformativ.de/git/katriawm/file/README.html";
+    description = "A non-reparenting, dynamic window manager with decorations";
+    license = licenses.mit;
+    maintainers = with maintainers; [ AndersonTorres ];
+    inherit (libX11.meta) platforms;
+  };
+})

pkgs/applications/window-managers/sxhkd/default.nix

@@ -1,27 +0,0 @@
-{ lib, stdenv, fetchFromGitHub, asciidoc, libxcb, xcbutil, xcbutilkeysyms
-, xcbutilwm
-}:
-
-stdenv.mkDerivation rec {
-  pname = "sxhkd";
-  version = "0.6.2";
-
-  src = fetchFromGitHub {
-    owner = "baskerville";
-    repo = "sxhkd";
-    rev = version;
-    sha256 = "1winwzdy9yxvxnrv8gqpigl9y0c2px27mnms62bdilp4x6llrs9r";
-  };
-
-  buildInputs = [ asciidoc libxcb xcbutil xcbutilkeysyms xcbutilwm ];
-
-  makeFlags = [ "PREFIX=$(out)" ];
-
-  meta = with lib; {
-    description = "Simple X hotkey daemon";
-    homepage = "https://github.com/baskerville/sxhkd";
-    license = licenses.bsd2;
-    maintainers = with maintainers; [ vyp ];
-    platforms = platforms.linux;
-  };
-}

pkgs/tools/X11/sxhkd/default.nix

@@ -0,0 +1,42 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, asciidoc
+, libxcb
+, xcbutil
+, xcbutilkeysyms
+, xcbutilwm
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "sxhkd";
+  version = "0.6.2";
+
+  src = fetchFromGitHub {
+    owner = "baskerville";
+    repo = "sxhkd";
+    rev = finalAttrs.version;
+    hash = "sha256-OelMqenk0tiWMLraekS/ggGf6IsXP7Sz7bv75NvnNvI=";
+  };
+
+  nativeBuildInputs = [
+    asciidoc
+  ];
+
+  buildInputs = [
+    libxcb
+    xcbutil
+    xcbutilkeysyms
+    xcbutilwm
+  ];
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Simple X hotkey daemon";
+    homepage = "https://github.com/baskerville/sxhkd";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ vyp AndersonTorres ];
+    platforms = platforms.linux;
+  };
+})

pkgs/top-level/all-packages.nix

@@ -8503,6 +8503,8 @@ with pkgs;
 
   katana = callPackage ../tools/security/katana { };
 
+  katriawm = callPackage ../applications/window-managers/katriawm { };
+
   kbdd = callPackage ../applications/window-managers/kbdd { };
 
   kbs2 = callPackage ../tools/security/kbs2 {
@@ -31031,7 +31033,7 @@ with pkgs;
 
   sndpeek = callPackage ../applications/audio/sndpeek { };
 
-  sxhkd = callPackage ../applications/window-managers/sxhkd { };
+  sxhkd = callPackage ../tools/X11/sxhkd { };
 
   mpop = callPackage ../applications/networking/mpop {
     inherit (darwin.apple_sdk.frameworks) Security;