mysql57: drop

Mysql 5.7 is not EOL yet, but is quite old and fully replaceable
by mysql 8.0 or mariadb.

nixos/tests/mysql/common.nix

@@ -4,7 +4,7 @@
     inherit (pkgs.darwin.apple_sdk.frameworks) CoreServices;
   });
   mysqlPackages = {
-    inherit (pkgs) mysql57 mysql80;
+    inherit (pkgs) mysql80;
   };
   mkTestName = pkg: "mariadb_${builtins.replaceStrings ["."] [""] (lib.versions.majorMinor pkg.version)}";
 }

pkgs/servers/sql/mysql/5.7.x.nix

@@ -1,90 +0,0 @@
-{ lib, stdenv, fetchurl, cmake, bison, pkg-config, nukeReferences
-, boost, libedit, libevent, lz4, ncurses, openssl, protobuf, readline, zlib, perl
-, cctools, CoreServices, developer_cmds
-, libtirpc, rpcsvc-proto, nixosTests
-}:
-
-# Note: zlib is not required; MySQL can use an internal zlib.
-
-let
-self = stdenv.mkDerivation rec {
-  pname = "mysql";
-  version = "5.7.39";
-
-  src = fetchurl {
-    url = "mirror://mysql/MySQL-5.7/${pname}-${version}.tar.gz";
-    sha256 = "sha256-ERw6ypGJfkUwOds5GkdSZeAg/ZIcuXMHwACEqI5NYQQ=";
-  };
-
-  preConfigure = lib.optionalString stdenv.isDarwin ''
-    ln -s /bin/ps $TMPDIR/ps
-    export PATH=$PATH:$TMPDIR
-  '';
-
-  nativeBuildInputs = [ bison cmake pkg-config nukeReferences ]
-    ++ lib.optionals (!stdenv.isDarwin) [ rpcsvc-proto ];
-
-  buildInputs = [ boost libedit libevent lz4 ncurses openssl protobuf readline zlib ]
-     ++ lib.optionals stdenv.isDarwin [ perl cctools CoreServices developer_cmds ]
-     ++ lib.optionals stdenv.isLinux [ libtirpc ];
-
-  outputs = [ "out" "static" ];
-
-  cmakeFlags = [
-    "-DWITH_SSL=yes"
-    "-DWITH_EMBEDDED_SERVER=yes"
-    "-DWITH_UNIT_TESTS=no"
-    "-DWITH_EDITLINE=system"
-    "-DWITH_LIBEVENT=system"
-    "-DWITH_LZ4=system"
-    "-DWITH_PROTOBUF=system"
-    "-DWITH_ZLIB=system"
-    "-DWITH_ARCHIVE_STORAGE_ENGINE=yes"
-    "-DWITH_BLACKHOLE_STORAGE_ENGINE=yes"
-    "-DWITH_FEDERATED_STORAGE_ENGINE=yes"
-    "-DHAVE_IPV6=yes"
-    "-DMYSQL_UNIX_ADDR=/run/mysqld/mysqld.sock"
-    "-DMYSQL_DATADIR=/var/lib/mysql"
-    "-DINSTALL_INFODIR=share/mysql/docs"
-    "-DINSTALL_MANDIR=share/man"
-    "-DINSTALL_PLUGINDIR=lib/mysql/plugin"
-    "-DINSTALL_SCRIPTDIR=bin"
-    "-DINSTALL_INCLUDEDIR=include/mysql"
-    "-DINSTALL_DOCREADMEDIR=share/mysql"
-    "-DINSTALL_SUPPORTFILESDIR=share/mysql"
-    "-DINSTALL_MYSQLSHAREDIR=share/mysql"
-    "-DINSTALL_MYSQLTESTDIR="
-    "-DINSTALL_DOCDIR=share/mysql/docs"
-    "-DINSTALL_SHAREDIR=share/mysql"
-  ];
-
-  CXXFLAGS = "-fpermissive -std=c++11";
-  NIX_LDFLAGS = lib.optionalString stdenv.isLinux "-lgcc_s";
-
-  prePatch = ''
-    sed -i -e "s|/usr/bin/libtool|libtool|" cmake/merge_archives.cmake.in
-  '';
-  postInstall = ''
-    nuke-refs "$out/share/mysql/docs/INFO_BIN"
-    moveToOutput "lib/*.a" $static
-    ln -s libmysqlclient${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib/libmysqlclient_r${stdenv.hostPlatform.extensions.sharedLibrary}
-  '';
-
-  passthru = {
-    client = self;
-    connector-c = self;
-    server = self;
-    mysqlVersion = "5.7";
-    tests = nixosTests.mysql.mysql57;
-  };
-
-  meta = with lib; {
-    homepage = "https://www.mysql.com/";
-    description = "The world's most popular open source database";
-    platforms = platforms.unix;
-    license = with licenses; [
-      artistic1 bsd0 bsd2 bsd3 bsdOriginal
-      gpl2 lgpl2 lgpl21 mit publicDomain licenses.zlib
-    ];
-  };
-}; in self

pkgs/top-level/aliases.nix

@@ -757,6 +757,7 @@ mapAliases ({
   mutt-with-sidebar = mutt; # Added 2022-09-17
   mysql-client = throw "'mysql-client' has been renamed to/replaced by 'mariadb.client'"; # Converted to throw 2022-09-24
   mysql = throw "'mysql' has been renamed to/replaced by 'mariadb'"; # Converted to throw 2022-09-24
+  mysql57 = throw "'mysql57' has been removed. Please use 'mysql80' or 'mariadb'";
 
   mesa_drivers = throw "'mesa_drivers' has been renamed to/replaced by 'mesa.drivers'"; # Converted to throw 2022-09-24
   mesa_noglu = throw "'mesa_noglu' has been renamed to/replaced by 'mesa'"; # Converted to throw 2022-02-22

pkgs/top-level/all-packages.nix

@@ -23761,14 +23761,6 @@ with pkgs;
   # removed in a few releases.
   influxdb2 = callPackage ../servers/nosql/influxdb2/combined.nix { };
 
-  mysql57 = callPackage ../servers/sql/mysql/5.7.x.nix {
-    inherit (darwin) cctools developer_cmds;
-    inherit (darwin.apple_sdk.frameworks) CoreServices;
-    boost = boost159;
-    protobuf = protobuf3_7;
-    openssl = openssl_1_1;
-  };
-
   mysql80 = callPackage ../servers/sql/mysql/8.0.x.nix {
     inherit (darwin) cctools developer_cmds DarwinTools;
     inherit (darwin.apple_sdk.frameworks) CoreServices;