diff --git a/pkgs/tools/misc/ccal/default.nix b/pkgs/tools/misc/ccal/default.nix
new file mode 100644
index 00000000000..55ccb7f774c
--- /dev/null
+++ b/pkgs/tools/misc/ccal/default.nix
@@ -0,0 +1,35 @@
+{ stdenv
+, lib
+, fetchurl
+, makeWrapper
+, ghostscript_headless  # for ps2pdf binary
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ccal";
+  version = "2.5.3";
+  src = fetchurl {
+    url = "http://ccal.chinesebay.com/ccal/${pname}-${version}.tar.gz";
+    sha256 = "sha256-PUy9yfkFzgKrSEBB+79/C3oxmuajUMbBbWNuGlpQ35Y=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  makeFlags = [ "CXX:=$(CXX)" "BINDIR=$(out)/bin" "MANDIR=$(out)/share/man" ];
+  installTargets = [ "install" "install-man" ];
+
+  # ccalpdf depends on a `ps2pdf` binary in PATH
+  postFixup = ''
+    wrapProgram $out/bin/ccalpdf \
+      --prefix PATH : ${lib.makeBinPath [ ghostscript_headless ]}:$out/bin
+  '';
+
+  meta = {
+    homepage = "http://ccal.chinesebay.com/ccal.htm";
+    description = "Command line Chinese calendar viewer, similar to cal";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ sharzy ];
+    platforms = lib.platforms.all;
+  };
+}
+
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index b3cfb3582c4..3f8a634331c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -384,6 +384,8 @@ with pkgs;
 
   btdu = callPackage ../tools/misc/btdu { };
 
+  ccal = callPackage ../tools/misc/ccal { };
+
   cereal = callPackage ../development/libraries/cereal { };
 
   certgraph = callPackage ../tools/security/certgraph { };