bilibili: init at 1.9.2-1

pkgs/applications/video/bilibili/default.nix

@@ -0,0 +1,48 @@
+{ lib
+, stdenv
+, fetchurl
+, electron
+, makeWrapper
+}:
+
+stdenv.mkDerivation rec {
+  pname = "bilibili";
+  version = "1.9.2-1";
+  src = fetchurl {
+    url = "https://github.com/msojocs/bilibili-linux/releases/download/v${version}/io.github.msojocs.bilibili_${version}_amd64.deb";
+    hash = "sha256-y3dUBImvcIG89m82RaIOa0cxJXIAIGa+n3FJkASacaY=";
+  };
+
+  unpackPhase = ''
+    runHook preUnpack
+
+    ar x $src
+    tar xf data.tar.xz
+
+    runHook postUnpack
+  '';
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp -r usr/share $out/share
+    sed -i "s|Exec=.*|Exec=$out/bin/bilibili|" $out/share/applications/*.desktop
+    cp -r opt/apps/io.github.msojocs.bilibili/files/bin/app $out/opt
+    makeWrapper ${electron}/bin/electron $out/bin/bilibili \
+      --argv0 "bilibili" \
+      --add-flags "$out/opt/app.asar"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Electron-based bilibili desktop client";
+    homepage = "https://github.com/msojocs/bilibili-linux";
+    license = licenses.mit;
+    maintainers = with maintainers; [ jedsek ];
+    platforms = platforms.unix;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -3802,6 +3802,8 @@ with pkgs;
 
   biliass = with python3.pkgs; toPythonApplication biliass;
 
+  bilibili = callPackage ../applications/video/bilibili { };
+
   bindfs = callPackage ../tools/filesystems/bindfs { };
 
   binwalk = with python3Packages; toPythonApplication binwalk;