openssh: 8.4p1 -> 8.5p1 and refactor
Also split out the variants of the package because I'm sick of waiting for random patches to be updated before I can update my unpatched openssh. Also make pname correspond to the attribute name.
This commit is contained in:
parent
8b84804837
commit
c99c4998fd
115
pkgs/tools/networking/openssh/common.nix
Normal file
115
pkgs/tools/networking/openssh/common.nix
Normal file
|
@ -0,0 +1,115 @@
|
||||||
|
{ pname
|
||||||
|
, version
|
||||||
|
, extraDesc ? ""
|
||||||
|
, src
|
||||||
|
, extraPatches ? []
|
||||||
|
, extraNativeBuildInputs ? []
|
||||||
|
}:
|
||||||
|
|
||||||
|
{ lib, stdenv
|
||||||
|
, fetchurl
|
||||||
|
, fetchpatch
|
||||||
|
, zlib
|
||||||
|
, openssl
|
||||||
|
, libedit
|
||||||
|
, pkg-config
|
||||||
|
, pam
|
||||||
|
, etcDir ? null
|
||||||
|
, withKerberos ? true
|
||||||
|
, kerberos
|
||||||
|
, libfido2
|
||||||
|
, withFIDO ? stdenv.hostPlatform.isUnix && !stdenv.hostPlatform.isMusl
|
||||||
|
, linkOpenssl ? true
|
||||||
|
}:
|
||||||
|
|
||||||
|
with lib;
|
||||||
|
stdenv.mkDerivation rec {
|
||||||
|
inherit pname version src;
|
||||||
|
|
||||||
|
patches = [
|
||||||
|
./locale_archive.patch
|
||||||
|
|
||||||
|
# See discussion in https://github.com/NixOS/nixpkgs/pull/16966
|
||||||
|
./dont_create_privsep_path.patch
|
||||||
|
] ++ extraPatches;
|
||||||
|
|
||||||
|
postPatch =
|
||||||
|
# On Hydra this makes installation fail (sometimes?),
|
||||||
|
# and nix store doesn't allow such fancy permission bits anyway.
|
||||||
|
''
|
||||||
|
substituteInPlace Makefile.in --replace '$(INSTALL) -m 4711' '$(INSTALL) -m 0711'
|
||||||
|
'';
|
||||||
|
|
||||||
|
nativeBuildInputs = [ pkg-config ]
|
||||||
|
++ optional withKerberos kerberos.dev
|
||||||
|
++ extraNativeBuildInputs;
|
||||||
|
buildInputs = [ zlib openssl libedit ]
|
||||||
|
++ optional withFIDO libfido2
|
||||||
|
++ optional withKerberos kerberos
|
||||||
|
++ optional stdenv.isLinux pam;
|
||||||
|
|
||||||
|
preConfigure = ''
|
||||||
|
# Setting LD causes `configure' and `make' to disagree about which linker
|
||||||
|
# to use: `configure' wants `gcc', but `make' wants `ld'.
|
||||||
|
unset LD
|
||||||
|
''
|
||||||
|
# Upstream build system does not support static build, so we fall back
|
||||||
|
# on fragile patching of configure script.
|
||||||
|
#
|
||||||
|
# libedit is found by pkg-config, but without --static flag, required
|
||||||
|
# to get also transitive dependencies for static linkage, hence sed
|
||||||
|
# expression.
|
||||||
|
#
|
||||||
|
# Kerberos can be found either by krb5-config or by fall-back shell
|
||||||
|
# code in openssh's configure.ac. Neither of them support static
|
||||||
|
# build, but patching code for krb5-config is simpler, so to get it
|
||||||
|
# into PATH, kerberos.dev is added into buildInputs.
|
||||||
|
+ optionalString stdenv.hostPlatform.isStatic ''
|
||||||
|
sed -i "s,PKGCONFIG --libs,PKGCONFIG --libs --static,g" configure
|
||||||
|
sed -i 's#KRB5CONF --libs`#KRB5CONF --libs` -lkrb5support -lkeyutils#g' configure
|
||||||
|
sed -i 's#KRB5CONF --libs gssapi`#KRB5CONF --libs gssapi` -lkrb5support -lkeyutils#g' configure
|
||||||
|
'';
|
||||||
|
|
||||||
|
# I set --disable-strip because later we strip anyway. And it fails to strip
|
||||||
|
# properly when cross building.
|
||||||
|
configureFlags = [
|
||||||
|
"--sbindir=\${out}/bin"
|
||||||
|
"--localstatedir=/var"
|
||||||
|
"--with-pid-dir=/run"
|
||||||
|
"--with-mantype=man"
|
||||||
|
"--with-libedit=yes"
|
||||||
|
"--disable-strip"
|
||||||
|
(if stdenv.isLinux then "--with-pam" else "--without-pam")
|
||||||
|
] ++ optional (etcDir != null) "--sysconfdir=${etcDir}"
|
||||||
|
++ optional withFIDO "--with-security-key-builtin=yes"
|
||||||
|
++ optional withKerberos (assert kerberos != null; "--with-kerberos5=${kerberos}")
|
||||||
|
++ optional stdenv.isDarwin "--disable-libutil"
|
||||||
|
++ optional (!linkOpenssl) "--without-openssl";
|
||||||
|
|
||||||
|
buildFlags = [ "SSH_KEYSIGN=ssh-keysign" ];
|
||||||
|
|
||||||
|
enableParallelBuilding = true;
|
||||||
|
|
||||||
|
hardeningEnable = [ "pie" ];
|
||||||
|
|
||||||
|
postInstall = ''
|
||||||
|
# Install ssh-copy-id, it's very useful.
|
||||||
|
cp contrib/ssh-copy-id $out/bin/
|
||||||
|
chmod +x $out/bin/ssh-copy-id
|
||||||
|
cp contrib/ssh-copy-id.1 $out/share/man/man1/
|
||||||
|
'';
|
||||||
|
|
||||||
|
installTargets = [ "install-nokeys" ];
|
||||||
|
installFlags = [
|
||||||
|
"sysconfdir=\${out}/etc/ssh"
|
||||||
|
];
|
||||||
|
|
||||||
|
meta = {
|
||||||
|
description = "An implementation of the SSH protocol${extraDesc}";
|
||||||
|
homepage = "https://www.openssh.com/";
|
||||||
|
changelog = "https://www.openssh.com/releasenotes.html";
|
||||||
|
license = licenses.bsd2;
|
||||||
|
platforms = platforms.unix ++ platforms.windows;
|
||||||
|
maintainers = with maintainers; [ eelco aneeshusa ];
|
||||||
|
};
|
||||||
|
}
|
|
@ -1,141 +1,63 @@
|
||||||
{ lib, stdenv
|
{ callPackage, fetchurl, fetchpatch, autoreconfHook }:
|
||||||
, pkgs
|
|
||||||
, fetchurl
|
|
||||||
, fetchpatch
|
|
||||||
, zlib
|
|
||||||
, openssl
|
|
||||||
, libedit
|
|
||||||
, pkg-config
|
|
||||||
, pam
|
|
||||||
, autoreconfHook
|
|
||||||
, etcDir ? null
|
|
||||||
, hpnSupport ? false
|
|
||||||
, withKerberos ? true
|
|
||||||
, withGssapiPatches ? false
|
|
||||||
, kerberos
|
|
||||||
, libfido2
|
|
||||||
, withFIDO ? stdenv.hostPlatform.isUnix && !stdenv.hostPlatform.isMusl
|
|
||||||
, linkOpenssl ? true
|
|
||||||
}:
|
|
||||||
|
|
||||||
let
|
let
|
||||||
|
common = opts: callPackage (import ./common.nix opts) {};
|
||||||
|
in {
|
||||||
|
|
||||||
version = "8.4p1";
|
openssh = common rec {
|
||||||
|
pname = "openssh";
|
||||||
|
version = "8.5p1";
|
||||||
|
|
||||||
# **please** update this patch when you update to a new openssh release.
|
src = fetchurl {
|
||||||
gssapiPatch = fetchpatch {
|
url = "mirror://openbsd/OpenSSH/portable/openssh-${version}.tar.gz";
|
||||||
name = "openssh-gssapi.patch";
|
sha256 = "09gc8rv7728chxraab85dzkdikaw4aph1wlcwcc9kai9si0kybzm";
|
||||||
url = "https://salsa.debian.org/ssh-team/openssh/raw/debian/1%25${version}-2/debian/patches/gssapi.patch";
|
};
|
||||||
sha256 = "1z1ckzimlkm1dmr9f5fqjnjg28gsqcwx6xka0klak857548d2lp2";
|
|
||||||
|
extraPatches = [ ./ssh-keysign-8.5.patch ];
|
||||||
};
|
};
|
||||||
|
|
||||||
in
|
openssh_hpn = common rec {
|
||||||
with lib;
|
pname = "openssh-with-hpn";
|
||||||
stdenv.mkDerivation rec {
|
version = "8.4p1";
|
||||||
pname = "openssh";
|
extraDesc = " with high performance networking patches";
|
||||||
inherit version;
|
|
||||||
|
|
||||||
src = if hpnSupport then
|
src = fetchurl {
|
||||||
fetchurl {
|
url = "https://github.com/rapier1/openssh-portable/archive/hpn-KitchenSink-${builtins.replaceStrings [ "." "p" ] [ "_" "_P" ] version}.tar.gz";
|
||||||
url = "https://github.com/rapier1/openssh-portable/archive/hpn-KitchenSink-${replaceStrings [ "." "p" ] [ "_" "_P" ] version}.tar.gz";
|
sha256 = "1x2afjy1isslbg7qlvhhs4zhj2c8q2h1ljz0fc5b4h9pqcm9j540";
|
||||||
sha256 = "1x2afjy1isslbg7qlvhhs4zhj2c8q2h1ljz0fc5b4h9pqcm9j540";
|
};
|
||||||
}
|
|
||||||
else
|
|
||||||
fetchurl {
|
|
||||||
url = "mirror://openbsd/OpenSSH/portable/${pname}-${version}.tar.gz";
|
|
||||||
sha256 = "091b3pxdlj47scxx6kkf4agkx8c8sdacdxx8m1dw1cby80pd40as";
|
|
||||||
};
|
|
||||||
|
|
||||||
patches =
|
extraPatches = [
|
||||||
[
|
./ssh-keysign-8.4.patch
|
||||||
./locale_archive.patch
|
|
||||||
|
|
||||||
# See discussion in https://github.com/NixOS/nixpkgs/pull/16966
|
|
||||||
./dont_create_privsep_path.patch
|
|
||||||
|
|
||||||
./ssh-keysign.patch
|
|
||||||
|
|
||||||
# See https://github.com/openssh/openssh-portable/pull/206
|
# See https://github.com/openssh/openssh-portable/pull/206
|
||||||
./ssh-copy-id-fix-eof.patch
|
./ssh-copy-id-fix-eof.patch
|
||||||
]
|
];
|
||||||
++ optional withGssapiPatches (assert withKerberos; gssapiPatch);
|
|
||||||
|
|
||||||
postPatch =
|
extraNativeBuildInputs = [ autoreconfHook ];
|
||||||
# On Hydra this makes installation fail (sometimes?),
|
};
|
||||||
# and nix store doesn't allow such fancy permission bits anyway.
|
|
||||||
''
|
|
||||||
substituteInPlace Makefile.in --replace '$(INSTALL) -m 4711' '$(INSTALL) -m 0711'
|
|
||||||
'';
|
|
||||||
|
|
||||||
nativeBuildInputs = [ pkg-config ]
|
openssh_gssapi = common rec {
|
||||||
++ optional (hpnSupport || withGssapiPatches) autoreconfHook
|
pname = "openssh-with-gssapi";
|
||||||
++ optional withKerberos pkgs.kerberos.dev;
|
version = "8.4p1";
|
||||||
buildInputs = [ zlib openssl libedit pam ]
|
extraDesc = " with GSSAPI support";
|
||||||
++ optional withFIDO libfido2
|
|
||||||
++ optional withKerberos kerberos;
|
|
||||||
|
|
||||||
preConfigure = ''
|
src = fetchurl {
|
||||||
# Setting LD causes `configure' and `make' to disagree about which linker
|
url = "mirror://openbsd/OpenSSH/portable/openssh-${version}.tar.gz";
|
||||||
# to use: `configure' wants `gcc', but `make' wants `ld'.
|
sha256 = "091b3pxdlj47scxx6kkf4agkx8c8sdacdxx8m1dw1cby80pd40as";
|
||||||
unset LD
|
};
|
||||||
''
|
|
||||||
# Upstream build system does not support static build, so we fall back
|
|
||||||
# on fragile patching of configure script.
|
|
||||||
#
|
|
||||||
# libedit is found by pkg-config, but without --static flag, required
|
|
||||||
# to get also transitive dependencies for static linkage, hence sed
|
|
||||||
# expression.
|
|
||||||
#
|
|
||||||
# Kerberos can be found either by krb5-config or by fall-back shell
|
|
||||||
# code in openssh's configure.ac. Neither of them support static
|
|
||||||
# build, but patching code for krb5-config is simpler, so to get it
|
|
||||||
# into PATH, kerberos.dev is added into buildInputs.
|
|
||||||
+ optionalString stdenv.hostPlatform.isStatic ''
|
|
||||||
sed -i "s,PKGCONFIG --libs,PKGCONFIG --libs --static,g" configure
|
|
||||||
sed -i 's#KRB5CONF --libs`#KRB5CONF --libs` -lkrb5support -lkeyutils#g' configure
|
|
||||||
sed -i 's#KRB5CONF --libs gssapi`#KRB5CONF --libs gssapi` -lkrb5support -lkeyutils#g' configure
|
|
||||||
'';
|
|
||||||
|
|
||||||
# I set --disable-strip because later we strip anyway. And it fails to strip
|
extraPatches = [
|
||||||
# properly when cross building.
|
./ssh-keysign-8.4.patch
|
||||||
configureFlags = [
|
|
||||||
"--sbindir=\${out}/bin"
|
|
||||||
"--localstatedir=/var"
|
|
||||||
"--with-pid-dir=/run"
|
|
||||||
"--with-mantype=man"
|
|
||||||
"--with-libedit=yes"
|
|
||||||
"--disable-strip"
|
|
||||||
(if pam != null then "--with-pam" else "--without-pam")
|
|
||||||
] ++ optional (etcDir != null) "--sysconfdir=${etcDir}"
|
|
||||||
++ optional withFIDO "--with-security-key-builtin=yes"
|
|
||||||
++ optional withKerberos (assert kerberos != null; "--with-kerberos5=${kerberos}")
|
|
||||||
++ optional stdenv.isDarwin "--disable-libutil"
|
|
||||||
++ optional (!linkOpenssl) "--without-openssl";
|
|
||||||
|
|
||||||
buildFlags = [ "SSH_KEYSIGN=ssh-keysign" ];
|
# See https://github.com/openssh/openssh-portable/pull/206
|
||||||
|
./ssh-copy-id-fix-eof.patch
|
||||||
|
|
||||||
enableParallelBuilding = true;
|
(fetchpatch {
|
||||||
|
name = "openssh-gssapi.patch";
|
||||||
|
url = "https://salsa.debian.org/ssh-team/openssh/raw/debian/1%25${version}-2/debian/patches/gssapi.patch";
|
||||||
|
sha256 = "1z1ckzimlkm1dmr9f5fqjnjg28gsqcwx6xka0klak857548d2lp2";
|
||||||
|
})
|
||||||
|
];
|
||||||
|
|
||||||
hardeningEnable = [ "pie" ];
|
extraNativeBuildInputs = [ autoreconfHook ];
|
||||||
|
|
||||||
postInstall = ''
|
|
||||||
# Install ssh-copy-id, it's very useful.
|
|
||||||
cp contrib/ssh-copy-id $out/bin/
|
|
||||||
chmod +x $out/bin/ssh-copy-id
|
|
||||||
cp contrib/ssh-copy-id.1 $out/share/man/man1/
|
|
||||||
'';
|
|
||||||
|
|
||||||
installTargets = [ "install-nokeys" ];
|
|
||||||
installFlags = [
|
|
||||||
"sysconfdir=\${out}/etc/ssh"
|
|
||||||
];
|
|
||||||
|
|
||||||
meta = {
|
|
||||||
description = "An implementation of the SSH protocol";
|
|
||||||
homepage = "https://www.openssh.com/";
|
|
||||||
changelog = "https://www.openssh.com/releasenotes.html";
|
|
||||||
license = lib.licenses.bsd2;
|
|
||||||
platforms = platforms.unix ++ platforms.windows;
|
|
||||||
maintainers = with maintainers; [ eelco aneeshusa ];
|
|
||||||
};
|
};
|
||||||
}
|
}
|
||||||
|
|
24
pkgs/tools/networking/openssh/ssh-keysign-8.5.patch
Normal file
24
pkgs/tools/networking/openssh/ssh-keysign-8.5.patch
Normal file
|
@ -0,0 +1,24 @@
|
||||||
|
diff --git a/pathnames.h b/pathnames.h
|
||||||
|
index cb44caa4..354fdf05 100644
|
||||||
|
--- a/pathnames.h
|
||||||
|
+++ b/pathnames.h
|
||||||
|
@@ -124,7 +124,7 @@
|
||||||
|
|
||||||
|
/* Location of ssh-keysign for hostbased authentication */
|
||||||
|
#ifndef _PATH_SSH_KEY_SIGN
|
||||||
|
-#define _PATH_SSH_KEY_SIGN "/usr/libexec/ssh-keysign"
|
||||||
|
+#define _PATH_SSH_KEY_SIGN "ssh-keysign"
|
||||||
|
#endif
|
||||||
|
|
||||||
|
/* Location of ssh-pkcs11-helper to support keys in tokens */
|
||||||
|
--- a/sshconnect2.c
|
||||||
|
+++ b/sshconnect2.c
|
||||||
|
@@ -2021,7 +2021,7 @@
|
||||||
|
|
||||||
|
debug3_f("[child] pid=%ld, exec %s",
|
||||||
|
(long)getpid(), _PATH_SSH_KEY_SIGN);
|
||||||
|
- execl(_PATH_SSH_KEY_SIGN, _PATH_SSH_KEY_SIGN, (char *)NULL);
|
||||||
|
+ execlp(_PATH_SSH_KEY_SIGN, _PATH_SSH_KEY_SIGN, (char *)NULL);
|
||||||
|
fatal_f("exec(%s): %s", _PATH_SSH_KEY_SIGN,
|
||||||
|
strerror(errno));
|
||||||
|
}
|
|
@ -6842,20 +6842,19 @@ in
|
||||||
|
|
||||||
opensm = callPackage ../tools/networking/opensm { };
|
opensm = callPackage ../tools/networking/opensm { };
|
||||||
|
|
||||||
openssh =
|
opensshPackages = dontRecurseIntoAttrs (callPackage ../tools/networking/openssh {});
|
||||||
callPackage ../tools/networking/openssh {
|
|
||||||
hpnSupport = false;
|
|
||||||
etcDir = "/etc/ssh";
|
|
||||||
pam = if stdenv.isLinux then pam else null;
|
|
||||||
};
|
|
||||||
|
|
||||||
openssh_hpn = pkgs.appendToName "with-hpn" (openssh.override {
|
openssh = opensshPackages.openssh.override {
|
||||||
hpnSupport = true;
|
etcDir = "/etc/ssh";
|
||||||
});
|
};
|
||||||
|
|
||||||
openssh_gssapi = pkgs.appendToName "with-gssapi" (openssh.override {
|
openssh_hpn = opensshPackages.openssh_hpn.override {
|
||||||
withGssapiPatches = true;
|
etcDir = "/etc/ssh";
|
||||||
});
|
};
|
||||||
|
|
||||||
|
openssh_gssapi = opensshPackages.openssh_gssapi.override {
|
||||||
|
etcDir = "/etc/ssh";
|
||||||
|
};
|
||||||
|
|
||||||
opensp = callPackage ../tools/text/sgml/opensp { };
|
opensp = callPackage ../tools/text/sgml/opensp { };
|
||||||
|
|
||||||
|
|
Loading…
Reference in a new issue