From dd72edcdae1ef5fb68e19e8d8220983d180a3d47 Mon Sep 17 00:00:00 2001
From: Thiago Franco de Moraes <totonixsame@gmail.com>
Date: Wed, 30 Sep 2020 14:26:27 -0300
Subject: [PATCH] python3Packages.wxpython_4_1: init at 4.1.0

---
 .../python-modules/wxPython/4.1.nix           | 75 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  8 ++
 2 files changed, 83 insertions(+)
 create mode 100644 pkgs/development/python-modules/wxPython/4.1.nix

diff --git a/pkgs/development/python-modules/wxPython/4.1.nix b/pkgs/development/python-modules/wxPython/4.1.nix
new file mode 100644
index 00000000000..6d07f8b5e28
--- /dev/null
+++ b/pkgs/development/python-modules/wxPython/4.1.nix
@@ -0,0 +1,75 @@
+{ lib
+, stdenv
+, fetchPypi
+, buildPythonPackage
+, which
+, pkgconfig
+, python
+, isPy27
+, pyopengl
+, doxygen
+, cairo
+, ncurses
+, pango
+, wxGTK
+}:
+let
+  dynamic-linker = stdenv.cc.bintools.dynamicLinker;
+in
+buildPythonPackage rec {
+  pname = "wxPython";
+  version = "4.1.0";
+  disabled = isPy27;
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "12x4ci5q7qni4rkfiq6lnpn1fk8b0sfc6dck5wyxkj2sfp5pa91f";
+  };
+
+  # https://github.com/NixOS/nixpkgs/issues/75759
+  # https://github.com/wxWidgets/Phoenix/issues/1316
+  doCheck = false;
+
+  nativeBuildInputs = [ which doxygen wxGTK pkgconfig ];
+
+  buildInputs = [
+    wxGTK.gtk
+    ncurses
+  ];
+
+  DOXYGEN = "${doxygen}/bin/doxygen";
+
+  preConfigure = lib.optionalString (!stdenv.isDarwin) ''
+    substituteInPlace wx/lib/wxcairo/wx_pycairo.py \
+      --replace 'cairoLib = None' 'cairoLib = ctypes.CDLL("${cairo}/lib/libcairo.so")'
+    substituteInPlace wx/lib/wxcairo/wx_pycairo.py \
+      --replace '_dlls = dict()' '_dlls = {k: ctypes.CDLL(v) for k, v in [
+        ("gdk",        "${wxGTK.gtk}/lib/libgtk-x11-3.0.so"),
+        ("pangocairo", "${pango.out}/lib/libpangocairo-1.0.so"),
+        ("appsvc",     None)
+      ]}'
+
+    # https://github.com/wxWidgets/Phoenix/pull/1584
+    # It'll be not needed in next version because https://github.com/wxWidgets/Phoenix/pull/1699
+    substituteInPlace build.py --replace "os.environ['PYTHONPATH'] = phoenixDir()" \
+      "os.environ['PYTHONPATH'] = os.environ['PYTHONPATH'] + os.pathsep + phoenixDir()"
+  '';
+
+  buildPhase = ''
+    ${python.interpreter} build.py -v --use_syswx dox etg --nodoc build_py
+  '';
+
+  installPhase = ''
+    ${python.interpreter} setup.py install --skip-build --prefix=$out
+    wrapPythonPrograms
+  '';
+
+  passthru = { inherit wxGTK; };
+
+  meta = with lib; {
+    description = "Cross platform GUI toolkit for Python, Phoenix version";
+    homepage = "http://wxpython.org/";
+    license = licenses.wxWindows;
+    maintainers = with maintainers; [ tfmoraes ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index ce7e0f87469..044f30e7617 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -7689,6 +7689,14 @@ in {
     };
   };
 
+  wxPython_4_1 = callPackage ../development/python-modules/wxPython/4.1.nix {
+    inherit (pkgs) pkgconfig;
+    wxGTK = pkgs.wxGTK31.override {
+      withGtk2 = false;
+      withWebKit = true;
+    };
+  };
+
   wxPython = self.wxPython30;
 
   x11_hash = callPackage ../development/python-modules/x11_hash { };