From ebd9fb6cf397388137fc1e3fc3c252c9cd951bb8 Mon Sep 17 00:00:00 2001
From: Evgeny Egorochkin <phreedom.stdin@gmail.com>
Date: Mon, 28 Jun 2010 18:36:37 +0000
Subject: [PATCH] Added Quassel IRC client service

svn path=/nixos/trunk/; revision=22425
---
 modules/module-list.nix                 |  1 +
 modules/services/networking/quassel.nix | 97 +++++++++++++++++++++++++
 2 files changed, 98 insertions(+)
 create mode 100644 modules/services/networking/quassel.nix

diff --git a/modules/module-list.nix b/modules/module-list.nix
index 8e12fd14129..2925f5a1809 100644
--- a/modules/module-list.nix
+++ b/modules/module-list.nix
@@ -92,6 +92,7 @@
   ./services/networking/openvpn.nix
   ./services/networking/portmap.nix
   ./services/networking/privoxy.nix
+  ./services/networking/quassel.nix
   ./services/networking/ssh/lshd.nix
   ./services/networking/ssh/sshd.nix
   ./services/networking/tftpd.nix
diff --git a/modules/services/networking/quassel.nix b/modules/services/networking/quassel.nix
new file mode 100644
index 00000000000..d4795f3b57d
--- /dev/null
+++ b/modules/services/networking/quassel.nix
@@ -0,0 +1,97 @@
+{ config, pkgs, ... }:
+
+with pkgs.lib;
+
+let
+  quassel = pkgs.quassel.override { daemon = true; monolithic = false; client = false; };
+  cfg = config.services.quassel;
+in
+
+{
+
+  ###### interface
+
+  options = {
+  
+    services.quassel = {
+
+      enable = mkOption {
+        default = false;
+        description = ''
+          Whether to run the Quassel IRC client daemon.
+        '';
+      };
+
+      interface = mkOption {
+        default = "127.0.0.1";
+        description = ''
+          The interface the Quassel daemon will be listening to.  If `127.0.0.1',
+          only clients on the local host can connect to it; if `0.0.0.0', clients
+          can access it from any network interface.
+        '';
+      };
+
+      portNumber = mkOption {
+        default = 4242;
+        description = ''
+          The port number the Quassel daemon will be listening to.
+        '';
+      };
+
+      logFile = mkOption {
+        default = "/var/log/quassel.log";
+        description = "Location of the logfile of the Quassel daemon.";
+      };
+
+      dataDir = mkOption {
+        default = ''/home/${cfg.user}/.config/quassel-irc.org'';
+        description = ''
+          The directory holding configuration files, the SQlite database and the SSL Cert.
+        '';
+      };
+
+      user = mkOption {
+        default = "quassel";
+        description = ''
+          The user the Quassel daemon should run as.
+        '';
+      };
+
+    };
+
+  };
+  
+
+  ###### implementation
+
+  config = mkIf cfg.enable {
+
+    users.extraUsers = singleton
+      { name = cfg.user;
+        description = "Quassel IRC client daemon";
+      };
+    
+
+    jobs.quassel =
+      { description = "Quassel IRC client daemon";
+
+        startOn = "ip-up";
+
+        preStart = ''
+            mkdir -p ${cfg.dataDir}
+            chown ${cfg.user} ${cfg.dataDir}
+            touch ${cfg.logFile} && chown ${cfg.user} ${cfg.logFile}
+        '';
+
+        exec = ''
+            ${pkgs.su}/bin/su -s ${pkgs.stdenv.shell} ${cfg.user} \
+                -c '${quassel}/bin/quasselcore --listen=${cfg.interface}\
+                    --port=${toString cfg.portNumber} --configdir=${cfg.dataDir} --logfile=${cfg.logFile}'
+        '';
+      };
+
+    environment.systemPackages = [ quassel ];
+
+  };
+  
+}