Merge pull request #136737 from SuperSandro2000/tauon

pkgs/applications/audio/tauon/default.nix

@@ -0,0 +1,109 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, pkg-config
+, python3Packages
+, ffmpeg
+, flac
+, gobject-introspection
+, gtk3
+, libnotify
+, libsamplerate
+, libvorbis
+, mpg123
+, libopenmpt
+, opusfile
+, pango
+, pulseaudio
+}:
+
+stdenv.mkDerivation rec {
+  pname = "tauon";
+  version = "6.7.1";
+
+  src = fetchFromGitHub {
+    owner = "Taiko2k";
+    repo = "TauonMusicBox";
+    rev = "v${version}";
+    sha256 = "1hm82yfq7q2akrrvff3vmwrd3bz34d2dk8jzhnizhnhar6xc6fzp";
+  };
+
+  postPatch = ''
+    substituteInPlace tauon.py \
+      --replace 'install_mode = False' 'install_mode = True' \
+      --replace 'install_directory = os.path.dirname(__file__)' 'install_directory = "${placeholder "out"}/share/tauon"'
+
+    substituteInPlace t_modules/t_main.py \
+      --replace 'install_mode = False' 'install_mode = True' \
+      --replace 'install_directory = sys.path[0]' 'install_directory = "${placeholder "out"}/share/tauon"' \
+      --replace 'libopenmpt.so' '${lib.getLib libopenmpt}/lib/libopenmpt.so' \
+      --replace 'lib/libphazor.so' '../../lib/libphazor.so'
+
+    substituteInPlace t_modules/t_phazor.py \
+      --replace 'lib/libphazor.so' '../../lib/libphazor.so'
+
+    patchShebangs compile-phazor.sh
+  '';
+
+  postBuild = ''
+    ./compile-phazor.sh
+  '';
+
+  nativeBuildInputs = [
+    pkg-config
+    python3Packages.wrapPython
+  ];
+
+  buildInputs = [
+    flac
+    gobject-introspection
+    gtk3
+    libnotify
+    libopenmpt
+    libsamplerate
+    libvorbis
+    mpg123
+    opusfile
+    pango
+    pulseaudio
+  ];
+
+  pythonPath = with python3Packages; [
+    dbus-python
+    isounidecode
+    musicbrainzngs
+    mutagen
+    pillow
+    pulsectl
+    pycairo
+    pylast
+    pygobject3
+    pylyrics
+    pysdl2
+    requests
+    send2trash
+  ];
+
+  makeWrapperArgs = [
+    "--prefix PATH : ${lib.makeBinPath [ffmpeg]}"
+    "--prefix PYTHONPATH : $out/share/tauon"
+    "--set GI_TYPELIB_PATH $GI_TYPELIB_PATH"
+  ];
+
+  installPhase = ''
+    install -Dm755 tauon.py $out/bin/tauon
+    mkdir -p $out/share/tauon
+    cp -r lib $out
+    cp -r assets input.txt t_modules theme $out/share/tauon
+
+    wrapPythonPrograms
+  '';
+
+  meta = with lib; {
+    description = "The Linux desktop music player from the future";
+    homepage = "https://tauonmusicbox.rocks/";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+    platforms = platforms.linux;
+  };
+}

pkgs/development/python-modules/isounidecode/default.nix

@@ -0,0 +1,23 @@
+{ lib, buildPythonPackage, fetchPypi }:
+
+buildPythonPackage rec {
+  pname = "isounidecode";
+  version = "0.3";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-TbCpYsY0GCbJpprKq8L5I6WxJNU6M1voku8pFzvDHFs=";
+  };
+
+  pythonImportsCheck = [ "isounidecode" ];
+
+  # no real tests included, fails to run
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Python package for conversion and transliteration of unicode into ascii or iso-8859-1";
+    homepage = "https://github.com/redvasily/isounidecode";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+  };
+}

pkgs/development/python-modules/pylyrics/default.nix

@@ -0,0 +1,30 @@
+{ lib, buildPythonPackage, fetchPypi, beautifulsoup4, requests }:
+
+buildPythonPackage rec {
+  pname = "pylyrics";
+  version = "1.1.0";
+
+  src = fetchPypi {
+    pname = "PyLyrics";
+    inherit version;
+    extension = "zip";
+    sha256 = "sha256-xfNujvDtO0h6kkLONMGfloTkGKW7/9XTZ9wdFgS0zQs=";
+  };
+
+  propagatedBuildInputs = [
+    beautifulsoup4
+    requests
+  ];
+
+  pythonImportsCheck = [ "PyLyrics" ];
+
+  # tries to connect to lyrics.wikia.com
+  doCheck = false;
+
+  meta = with lib; {
+    description = "A Pythonic Implementation of lyrics.wikia.com for getting lyrics of songs ";
+    homepage = "https://github.com/geekpradd/PyLyrics";
+    license = licenses.mit;
+    maintainers = with maintainers; [ SuperSandro2000 ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -905,6 +905,8 @@ with pkgs;
 
   sx-go = callPackage ../tools/security/sx-go { };
 
+  tauon = callPackage ../applications/audio/tauon { };
+
   tfk8s = callPackage ../tools/misc/tfk8s { };
 
   tnat64 = callPackage ../tools/networking/tnat64 { };

pkgs/top-level/python-packages.nix

@@ -3702,6 +3702,8 @@ in {
 
   isort = callPackage ../development/python-modules/isort { };
 
+  isounidecode = callPackage ../development/python-modules/isounidecode { };
+
   isoweek = callPackage ../development/python-modules/isoweek { };
 
   itanium_demangler = callPackage ../development/python-modules/itanium_demangler { };
@@ -6325,6 +6327,8 @@ in {
 
   pylutron-caseta = callPackage ../development/python-modules/pylutron-caseta { };
 
+  pylyrics = callPackage ../development/python-modules/pylyrics { };
+
   pylxd = callPackage ../development/python-modules/pylxd { };
 
   pylzma = callPackage ../development/python-modules/pylzma { };