Merge pull request #179450 from tomsiewert/changelogger-package

Add changelogger package

maintainers/maintainer-list.nix

@@ -12855,6 +12855,13 @@
     githubId = 6740669;
     name = "Tom Smeets";
   };
+  tomsiewert = {
+    email = "tom@siewert.io";
+    matrix = "@tom:frickel.earth";
+    github = "tomsiewert";
+    githubId = 8794235;
+    name = "Tom Siewert";
+  };
   toonn = {
     email = "nixpkgs@toonn.io";
     matrix = "@toonn:matrix.org";

pkgs/tools/misc/changelogger/default.nix

@@ -0,0 +1,43 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, installShellFiles
+}:
+
+buildGoModule rec {
+  pname = "changelogger";
+  version = "0.5.2";
+
+  src = fetchFromGitHub {
+    owner = "MarkusFreitag";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-r/rnYutjETlE05A/kVQEQ6ICtWXW6kMMfPrv1rw5f3Q=";
+  };
+
+  vendorSha256 = "sha256-RmLSuLZdYpA557xN7fkPZm5ektxvRHil1E2u1qR7EO0=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/MarkusFreitag/changelogger/cmd.BuildVersion=${version}"
+    "-X github.com/MarkusFreitag/changelogger/cmd.BuildDate=1970-01-01T00:00:00"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = ''
+    installShellCompletion --cmd changelogger \
+      --bash <($out/bin/changelogger completion bash) \
+      --fish <($out/bin/changelogger completion fish) \
+      --zsh <($out/bin/changelogger completion zsh)
+  '';
+
+  meta = with lib; {
+    description = "A tool to manage your changelog file in Markdown";
+    homepage = "https://github.com/MarkusFreitag/changelogger";
+    changelog = "https://github.com/MarkusFreitag/changelogger/blob/v${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ tomsiewert ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2183,6 +2183,8 @@ with pkgs;
 
   catcli = python3Packages.callPackage ../tools/filesystems/catcli { };
 
+  changelogger = callPackage ../tools/misc/changelogger { };
+
   chezmoi = callPackage ../tools/misc/chezmoi { };
 
   chipsec = callPackage ../tools/security/chipsec {