conversions were done using https://github.com/pennae/nix-doc-munge using (probably) rev f34e145 running nix-doc-munge nixos/**/*.nix nix-doc-munge --import nixos/**/*.nix the tool ensures that only changes that could affect the generated manual *but don't* are committed, other changes require manual review and are discarded.
77 lines
1.7 KiB
Nix
77 lines
1.7 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.sonarr;
|
|
in
|
|
{
|
|
options = {
|
|
services.sonarr = {
|
|
enable = mkEnableOption (lib.mdDoc "Sonarr");
|
|
|
|
dataDir = mkOption {
|
|
type = types.str;
|
|
default = "/var/lib/sonarr/.config/NzbDrone";
|
|
description = lib.mdDoc "The directory where Sonarr stores its data files.";
|
|
};
|
|
|
|
openFirewall = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Open ports in the firewall for the Sonarr web interface
|
|
'';
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "sonarr";
|
|
description = lib.mdDoc "User account under which Sonaar runs.";
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "sonarr";
|
|
description = lib.mdDoc "Group under which Sonaar runs.";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.tmpfiles.rules = [
|
|
"d '${cfg.dataDir}' 0700 ${cfg.user} ${cfg.group} - -"
|
|
];
|
|
|
|
systemd.services.sonarr = {
|
|
description = "Sonarr";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
Type = "simple";
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
ExecStart = "${pkgs.sonarr}/bin/NzbDrone -nobrowser -data='${cfg.dataDir}'";
|
|
Restart = "on-failure";
|
|
};
|
|
};
|
|
|
|
networking.firewall = mkIf cfg.openFirewall {
|
|
allowedTCPPorts = [ 8989 ];
|
|
};
|
|
|
|
users.users = mkIf (cfg.user == "sonarr") {
|
|
sonarr = {
|
|
group = cfg.group;
|
|
home = cfg.dataDir;
|
|
uid = config.ids.uids.sonarr;
|
|
};
|
|
};
|
|
|
|
users.groups = mkIf (cfg.group == "sonarr") {
|
|
sonarr.gid = config.ids.gids.sonarr;
|
|
};
|
|
};
|
|
}
|