the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
132 lines
3.9 KiB
Nix
132 lines
3.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
with lib;
|
|
let
|
|
|
|
cfg = config.services.gitDaemon;
|
|
|
|
in
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
services.gitDaemon = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Enable Git daemon, which allows public hosting of git repositories
|
|
without any access controls. This is mostly intended for read-only access.
|
|
|
|
You can allow write access by setting daemon.receivepack configuration
|
|
item of the repository to true. This is solely meant for a closed LAN setting
|
|
where everybody is friendly.
|
|
|
|
If you need any access controls, use something else.
|
|
'';
|
|
};
|
|
|
|
basePath = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
example = "/srv/git/";
|
|
description = lib.mdDoc ''
|
|
Remap all the path requests as relative to the given path. For example,
|
|
if you set base-path to /srv/git, then if you later try to pull
|
|
git://example.com/hello.git, Git daemon will interpret the path as /srv/git/hello.git.
|
|
'';
|
|
};
|
|
|
|
exportAll = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Publish all directories that look like Git repositories (have the objects
|
|
and refs subdirectories), even if they do not have the git-daemon-export-ok file.
|
|
|
|
If disabled, you need to touch .git/git-daemon-export-ok in each repository
|
|
you want the daemon to publish.
|
|
|
|
Warning: enabling this without a repository whitelist or basePath
|
|
publishes every git repository you have.
|
|
'';
|
|
};
|
|
|
|
repositories = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
example = [ "/srv/git" "/home/user/git/repo2" ];
|
|
description = lib.mdDoc ''
|
|
A whitelist of paths of git repositories, or directories containing repositories
|
|
all of which would be published. Paths must not end in "/".
|
|
|
|
Warning: leaving this empty and enabling exportAll publishes all
|
|
repositories in your filesystem or basePath if specified.
|
|
'';
|
|
};
|
|
|
|
listenAddress = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
example = "example.com";
|
|
description = lib.mdDoc "Listen on a specific IP address or hostname.";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 9418;
|
|
description = lib.mdDoc "Port to listen on.";
|
|
};
|
|
|
|
options = mkOption {
|
|
type = types.str;
|
|
default = "";
|
|
description = lib.mdDoc "Extra configuration options to be passed to Git daemon.";
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "git";
|
|
description = lib.mdDoc "User under which Git daemon would be running.";
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "git";
|
|
description = lib.mdDoc "Group under which Git daemon would be running.";
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
users.users = optionalAttrs (cfg.user == "git") {
|
|
git = {
|
|
uid = config.ids.uids.git;
|
|
group = "git";
|
|
description = "Git daemon user";
|
|
};
|
|
};
|
|
|
|
users.groups = optionalAttrs (cfg.group == "git") {
|
|
git.gid = config.ids.gids.git;
|
|
};
|
|
|
|
systemd.services.git-daemon = {
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
script = "${pkgs.git}/bin/git daemon --reuseaddr "
|
|
+ (optionalString (cfg.basePath != "") "--base-path=${cfg.basePath} ")
|
|
+ (optionalString (cfg.listenAddress != "") "--listen=${cfg.listenAddress} ")
|
|
+ "--port=${toString cfg.port} --user=${cfg.user} --group=${cfg.group} ${cfg.options} "
|
|
+ "--verbose " + (optionalString cfg.exportAll "--export-all ") + concatStringsSep " " cfg.repositories;
|
|
};
|
|
|
|
};
|
|
|
|
}
|