4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
46 lines
1.4 KiB
Nix
46 lines
1.4 KiB
Nix
{ lib, stdenv, fetchFromGitHub, cmake, fuse }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "unionfs-fuse";
|
|
version = "2.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "rpodgorny";
|
|
repo = "unionfs-fuse";
|
|
rev = "v${version}";
|
|
sha256 = "0bwx70x834qgqh53vqp18bhbxbsny80hz922rbgj8k9wj7cbfilm";
|
|
};
|
|
|
|
patches =
|
|
[ # Prevent the unionfs daemon from being killed during
|
|
# shutdown. See
|
|
# http://www.freedesktop.org/wiki/Software/systemd/RootStorageDaemons/
|
|
# for details.
|
|
./prevent-kill-on-shutdown.patch
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
buildInputs = [ fuse ];
|
|
|
|
# Put the unionfs mount helper in place as mount.unionfs-fuse. This makes it
|
|
# possible to do:
|
|
# mount -t unionfs-fuse none /dest -o dirs=/source1=RW,/source2=RO
|
|
#
|
|
# This must be done in preConfigure because the build process removes
|
|
# helper from the source directory during the build.
|
|
preConfigure = ''
|
|
mkdir -p $out/sbin
|
|
cp -a mount.unionfs $out/sbin/mount.unionfs-fuse
|
|
substituteInPlace $out/sbin/mount.unionfs-fuse --replace mount.fuse ${fuse}/sbin/mount.fuse
|
|
substituteInPlace $out/sbin/mount.unionfs-fuse --replace unionfs $out/bin/unionfs
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "FUSE UnionFS implementation";
|
|
homepage = "https://github.com/rpodgorny/unionfs-fuse";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ orivej ];
|
|
};
|
|
}
|