Includes several important fixes for macOS and Catalyst, Android NDKs, and iOS builds. - https://go.googlesource.com/mobile/+/8578da9835fd365e78a6e63048c103b27a53a82c - https://go.googlesource.com/mobile/+/76c259c465ba39f84de7e2751a666612ddca556b - https://go.googlesource.com/mobile/+/9cba7bc03c0fdba1b8fe7dfd476c2001656dde9e - https://go.googlesource.com/mobile/+/80cb72e7af8e71b65e7d9e59fb4ec5d620134608 - https://go.googlesource.com/mobile/+/6d8ad35e460371e979b330d80492cba19676f933 - https://go.googlesource.com/mobile/+/b5eb1abba0f2d9331b29a29967d535890e026cec Also moves use of `wrapProgram` to `postFixup` and dropped `ANDROID_NDK_HOME`. No longer necessary as `8578da98` detects it from `ANDROID_HOME`. Signed-off-by: Jakub Sokołowski <jakub@status.im>
66 lines
2.1 KiB
Nix
66 lines
2.1 KiB
Nix
{ stdenv, lib, fetchgit, buildGoModule, zlib, makeWrapper, xcodeenv, androidenv
|
|
, xcodeWrapperArgs ? { }
|
|
, xcodeWrapper ? xcodeenv.composeXcodeWrapper xcodeWrapperArgs
|
|
, withAndroidPkgs ? true
|
|
, androidPkgs ? androidenv.composeAndroidPackages {
|
|
includeNDK = true;
|
|
ndkVersion = "22.1.7171670";
|
|
} }:
|
|
|
|
buildGoModule {
|
|
pname = "gomobile";
|
|
version = "unstable-2022-05-18";
|
|
|
|
vendorSha256 = "sha256-AmOy3X+d2OD7ZLbFuy+SptdlgWbZJaXYEgO79M64ufE=";
|
|
|
|
src = fetchgit {
|
|
rev = "8578da9835fd365e78a6e63048c103b27a53a82c";
|
|
name = "gomobile";
|
|
url = "https://go.googlesource.com/mobile";
|
|
sha256 = "sha256-AOR/p+DW83f2+BOxm2rFXBCrotcIyunK3UzQ/dnauWY=";
|
|
};
|
|
|
|
subPackages = [ "bind" "cmd/gobind" "cmd/gomobile" ];
|
|
|
|
# Fails with: go: cannot find GOROOT directory
|
|
doCheck = false;
|
|
|
|
nativeBuildInputs = [ makeWrapper ]
|
|
++ lib.optionals stdenv.isDarwin [ xcodeWrapper ];
|
|
|
|
# Prevent a non-deterministic temporary directory from polluting the resulting object files
|
|
postPatch = ''
|
|
substituteInPlace cmd/gomobile/env.go --replace \
|
|
'tmpdir, err = ioutil.TempDir("", "gomobile-work-")' \
|
|
'tmpdir = filepath.Join(os.Getenv("NIX_BUILD_TOP"), "gomobile-work")'
|
|
substituteInPlace cmd/gomobile/init.go --replace \
|
|
'tmpdir, err = ioutil.TempDir(gomobilepath, "work-")' \
|
|
'tmpdir = filepath.Join(os.Getenv("NIX_BUILD_TOP"), "work")'
|
|
'';
|
|
|
|
# Necessary for GOPATH when using gomobile.
|
|
postInstall = ''
|
|
mkdir -p $out/src/golang.org/x
|
|
ln -s $src $out/src/golang.org/x/mobile
|
|
'';
|
|
|
|
postFixup = ''
|
|
for bin in $(ls $out/bin); do
|
|
wrapProgram $out/bin/$bin \
|
|
--suffix GOPATH : $out \
|
|
'' + lib.optionalString withAndroidPkgs ''
|
|
--prefix PATH : "${androidPkgs.androidsdk}/bin" \
|
|
--set-default ANDROID_HOME "${androidPkgs.androidsdk}/libexec/android-sdk" \
|
|
'' + ''
|
|
--prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ zlib ]}"
|
|
done
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A tool for building and running mobile apps written in Go";
|
|
homepage = "https://pkg.go.dev/golang.org/x/mobile/cmd/gomobile";
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ jakubgs ];
|
|
};
|
|
}
|