We do not use a "plugin system" for Git addons anymore, and therefore this directory is no longer useful. Indeed that directory is way more confusing, given that it includes more than mere Git addons, going from Bitbucket server command-line tools to complete rewrites of Git in exotic programming languages. Also, without this directory, the mental load of decision-making reduces a lot. When anyone is interested in including a new git-related tool, just put it into pkgs/applications/version-management, without apologies.
49 lines
1.2 KiB
Nix
49 lines
1.2 KiB
Nix
{ lib
|
|
, pythonPackages
|
|
, git
|
|
}:
|
|
|
|
pythonPackages.buildPythonApplication rec {
|
|
pname = "git-up";
|
|
version = "1.6.1";
|
|
|
|
src = pythonPackages.fetchPypi {
|
|
inherit pname version;
|
|
sha256 = "0gs791yb0cndg9879vayvcj329jwhzpk6wrf9ri12l5hg8g490za";
|
|
};
|
|
|
|
# git should be on path for tool to work correctly
|
|
propagatedBuildInputs = [
|
|
git
|
|
] ++ (with pythonPackages; [
|
|
click
|
|
colorama
|
|
docopt
|
|
gitpython
|
|
six
|
|
termcolor
|
|
]);
|
|
|
|
checkInputs = [ git pythonPackages.nose ]; # git needs to be on path
|
|
# 1. git fails to run as it cannot detect the email address, so we set it
|
|
# 2. $HOME is by default not a valid dir, so we have to set that too
|
|
# https://github.com/NixOS/nixpkgs/issues/12591
|
|
preCheck = ''
|
|
export HOME=$TMPDIR
|
|
git config --global user.email "nobody@example.com"
|
|
git config --global user.name "Nobody"
|
|
'';
|
|
|
|
postInstall = ''
|
|
rm -r $out/${pythonPackages.python.sitePackages}/PyGitUp/tests
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/msiemens/PyGitUp";
|
|
description = "A git pull replacement that rebases all local branches when pulling";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ peterhoeg ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|