Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/openttd/versions. These checks were done: - built on NixOS - ran ‘/nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0/bin/openttd -h’ got 0 exit code - ran ‘/nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0/bin/openttd --help’ got 0 exit code - ran ‘/nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0/bin/openttd help’ got 0 exit code - ran ‘/nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0/bin/.openttd-wrapped -h’ got 0 exit code - ran ‘/nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0/bin/.openttd-wrapped --help’ got 0 exit code - ran ‘/nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0/bin/.openttd-wrapped help’ got 0 exit code - found 1.8.0 with grep in /nix/store/m11nsq51szvkzqnlsb3k7skqzh2781jp-openttd-1.8.0 - directory tree listing: https://gist.github.com/8f8e59bc7bf394685911bd755a16c0a9
95 lines
3 KiB
Nix
95 lines
3 KiB
Nix
{ stdenv, fetchurl, fetchzip, pkgconfig, SDL, libpng, zlib, xz, freetype, fontconfig
|
|
, withOpenGFX ? true, withOpenSFX ? true, withOpenMSX ? true
|
|
, withFluidSynth ? true, audioDriver ? "alsa", fluidsynth, soundfont-fluid, procps
|
|
, writeScriptBin, makeWrapper
|
|
}:
|
|
|
|
let
|
|
opengfx = fetchzip {
|
|
url = "http://binaries.openttd.org/extra/opengfx/0.5.2/opengfx-0.5.2-all.zip";
|
|
sha256 = "1sjzwl8wfdj0izlx2qdq15bqiy1vzq7gq7drydfwwryk173ig5sa";
|
|
};
|
|
|
|
opensfx = fetchzip {
|
|
url = "http://binaries.openttd.org/extra/opensfx/0.2.3/opensfx-0.2.3-all.zip";
|
|
sha256 = "1bb167kszdd6dqbcdjrxxwab6b7y7jilhzi3qijdhprpm5gf1lp3";
|
|
};
|
|
|
|
openmsx = fetchzip {
|
|
url = "http://binaries.openttd.org/extra/openmsx/0.3.1/openmsx-0.3.1-all.zip";
|
|
sha256 = "0qnmfzz0v8vxrrvxnm7szphrlrlvhkwn3y92b4iy0b4b6yam0yd4";
|
|
};
|
|
|
|
playmidi = writeScriptBin "playmidi" ''
|
|
#!/bin/sh
|
|
trap "${procps}/bin/pkill fluidsynth" EXIT
|
|
${fluidsynth}/bin/fluidsynth -a ${audioDriver} -i ${soundfont-fluid}/share/soundfonts/FluidR3_GM2-2.sf2 $*
|
|
'';
|
|
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
name = "openttd-${version}";
|
|
version = "1.8.0";
|
|
|
|
src = fetchurl {
|
|
url = "http://binaries.openttd.org/releases/${version}/${name}-source.tar.xz";
|
|
sha256 = "0zq8xdg0k92p3s4j9x76591zaqz7k9ra69q008m209vdfffjvly2";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig makeWrapper ];
|
|
buildInputs = [ SDL libpng xz zlib freetype fontconfig ]
|
|
++ stdenv.lib.optionals withFluidSynth [ fluidsynth soundfont-fluid ];
|
|
|
|
prefixKey = "--prefix-dir=";
|
|
|
|
configureFlags = [
|
|
"--without-liblzo2"
|
|
];
|
|
|
|
makeFlags = "INSTALL_PERSONAL_DIR=";
|
|
|
|
postInstall = ''
|
|
mv $out/games/ $out/bin
|
|
|
|
${stdenv.lib.optionalString withOpenGFX ''
|
|
cp ${opengfx}/* $out/share/games/openttd/baseset
|
|
''}
|
|
|
|
mkdir -p $out/share/games/openttd/data
|
|
|
|
${stdenv.lib.optionalString withOpenSFX ''
|
|
cp ${opensfx}/*.{obs,cat} $out/share/games/openttd/data
|
|
''}
|
|
|
|
mkdir $out/share/games/openttd/baseset/openmsx
|
|
|
|
${stdenv.lib.optionalString withOpenMSX ''
|
|
cp ${openmsx}/*.{obm,mid} $out/share/games/openttd/baseset/openmsx
|
|
''}
|
|
|
|
${stdenv.lib.optionalString withFluidSynth ''
|
|
wrapProgram $out/bin/openttd \
|
|
--add-flags -m \
|
|
--add-flags extmidi:cmd=${playmidi}/bin/playmidi
|
|
''}
|
|
'';
|
|
|
|
meta = {
|
|
description = ''Open source clone of the Microprose game "Transport Tycoon Deluxe"'';
|
|
longDescription = ''
|
|
OpenTTD is a transportation economics simulator. In single player mode,
|
|
players control a transportation business, and use rail, road, sea, and air
|
|
transport to move goods and people around the simulated world.
|
|
|
|
In multiplayer networked mode, players may:
|
|
- play competitively as different businesses
|
|
- play cooperatively controlling the same business
|
|
- observe as spectators
|
|
'';
|
|
homepage = http://www.openttd.org/;
|
|
license = stdenv.lib.licenses.gpl2;
|
|
platforms = stdenv.lib.platforms.linux;
|
|
maintainers = with stdenv.lib.maintainers; [ jcumming the-kenny fpletz ];
|
|
};
|
|
}
|