At some point, I'd like to make another attempt at71f1f4884b
("openssl: stop static binaries referencing libs"), which was reverted in195c7da07d
. One problem with my previous attempt is that I moved OpenSSL's libraries to a lib output, but many dependent packages were hardcoding the out output as the location of the libraries. This patch fixes every such case I could find in the tree. It won't have any effect immediately, but will mean these packages will automatically use an OpenSSL lib output if it is reintroduced in future. This patch should cause very few rebuilds, because it shouldn't make any change at all to most packages I'm touching. The few rebuilds that are introduced come from when I've changed a package builder not to use variable names like openssl.out in scripts / substitution patterns, which would be confusing since they don't hardcode the output any more. I started by making the following global replacements: ${pkgs.openssl.out}/lib -> ${lib.getLib pkgs.openssl}/lib ${openssl.out}/lib -> ${lib.getLib openssl}/lib Then I removed the ".out" suffix when part of the argument to lib.makeLibraryPath, since that function uses lib.getLib internally. Then I fixed up cases where openssl was part of the -L flag to the compiler/linker, since that unambigously is referring to libraries. Then I manually investigated and fixed the following packages: - pycurl - citrix-workspace - ppp - wraith - unbound - gambit - acl2 I'm reasonably confindent in my fixes for all of them. For acl2, since the openssl library paths are manually provided above anyway, I don't think openssl is required separately as a build input at all. Removing it doesn't make a difference to the output size, the file list, or the closure. I've tested evaluation with the OfBorg meta checks, to protect against introducing evaluation failures.
132 lines
4.3 KiB
Nix
132 lines
4.3 KiB
Nix
{ bdbSupport ? true # build support for Berkeley DB repositories
|
|
, httpServer ? false # build Apache DAV module
|
|
, httpSupport ? true # client must support http
|
|
, pythonBindings ? false
|
|
, perlBindings ? false
|
|
, javahlBindings ? false
|
|
, saslSupport ? false
|
|
, lib, stdenv, fetchurl, apr, aprutil, zlib, sqlite, openssl, lz4, utf8proc
|
|
, autoconf, libtool
|
|
, apacheHttpd ? null, expat, swig ? null, jdk ? null, python3 ? null, py3c ? null, perl ? null
|
|
, sasl ? null, serf ? null
|
|
}:
|
|
|
|
assert bdbSupport -> aprutil.bdbSupport;
|
|
assert httpServer -> apacheHttpd != null;
|
|
assert pythonBindings -> swig != null && python3 != null && py3c != null;
|
|
assert javahlBindings -> jdk != null && perl != null;
|
|
|
|
let
|
|
# Update libtool for macOS 11 support
|
|
needsAutogen = stdenv.hostPlatform.isDarwin && lib.versionAtLeast stdenv.hostPlatform.darwinMinVersion "11";
|
|
|
|
common = { version, sha256, extraPatches ? [ ] }: stdenv.mkDerivation (rec {
|
|
inherit version;
|
|
pname = "subversion";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://apache/subversion/${pname}-${version}.tar.bz2";
|
|
inherit sha256;
|
|
};
|
|
|
|
# Can't do separate $lib and $bin, as libs reference bins
|
|
outputs = [ "out" "dev" "man" ];
|
|
|
|
nativeBuildInputs = lib.optionals needsAutogen [ autoconf libtool python3 ];
|
|
|
|
buildInputs = [ zlib apr aprutil sqlite openssl lz4 utf8proc ]
|
|
++ lib.optional httpSupport serf
|
|
++ lib.optionals pythonBindings [ python3 py3c ]
|
|
++ lib.optional perlBindings perl
|
|
++ lib.optional saslSupport sasl;
|
|
|
|
patches = [ ./apr-1.patch ] ++ extraPatches;
|
|
|
|
# We are hitting the following issue even with APR 1.6.x
|
|
# -> https://issues.apache.org/jira/browse/SVN-4813
|
|
# "-P" CPPFLAG is needed to build Python bindings and subversionClient
|
|
CPPFLAGS = [ "-P" ];
|
|
|
|
preConfigure = lib.optionalString needsAutogen ''
|
|
./autogen.sh
|
|
'';
|
|
|
|
configureFlags = [
|
|
(lib.withFeature bdbSupport "berkeley-db")
|
|
(lib.withFeatureAs httpServer "apxs" "${apacheHttpd.dev}/bin/apxs")
|
|
(lib.withFeatureAs (pythonBindings || perlBindings) "swig" swig)
|
|
(lib.withFeatureAs saslSupport "sasl" sasl)
|
|
(lib.withFeatureAs httpSupport "serf" serf)
|
|
"--disable-keychain"
|
|
"--with-zlib=${zlib.dev}"
|
|
"--with-sqlite=${sqlite.dev}"
|
|
] ++ lib.optionals javahlBindings [
|
|
"--enable-javahl"
|
|
"--with-jdk=${jdk}"
|
|
];
|
|
|
|
preBuild = ''
|
|
makeFlagsArray=(APACHE_LIBEXECDIR=$out/modules)
|
|
'';
|
|
|
|
postInstall = ''
|
|
if test -n "$pythonBindings"; then
|
|
make swig-py swig_pydir=$(toPythonPath $out)/libsvn swig_pydir_extra=$(toPythonPath $out)/svn
|
|
make install-swig-py swig_pydir=$(toPythonPath $out)/libsvn swig_pydir_extra=$(toPythonPath $out)/svn
|
|
fi
|
|
|
|
if test -n "$perlBindings"; then
|
|
make swig-pl-lib
|
|
make install-swig-pl-lib
|
|
cd subversion/bindings/swig/perl/native
|
|
perl Makefile.PL PREFIX=$out
|
|
make install
|
|
cd -
|
|
fi
|
|
|
|
mkdir -p $out/share/bash-completion/completions
|
|
cp tools/client-side/bash_completion $out/share/bash-completion/completions/subversion
|
|
|
|
for f in $out/lib/*.la $out/lib/python*/site-packages/*/*.la; do
|
|
substituteInPlace $f \
|
|
--replace "${expat.dev}/lib" "${expat.out}/lib" \
|
|
--replace "${zlib.dev}/lib" "${zlib.out}/lib" \
|
|
--replace "${sqlite.dev}/lib" "${sqlite.out}/lib" \
|
|
--replace "${openssl.dev}/lib" "${lib.getLib openssl}/lib"
|
|
done
|
|
'';
|
|
|
|
inherit perlBindings pythonBindings;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
checkInputs = [ python3 ];
|
|
doCheck = false; # fails 10 out of ~2300 tests
|
|
|
|
meta = with lib; {
|
|
description = "A version control system intended to be a compelling replacement for CVS in the open source community";
|
|
license = licenses.asl20;
|
|
homepage = "https://subversion.apache.org/";
|
|
maintainers = with maintainers; [ eelco lovek323 ];
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
};
|
|
|
|
} // lib.optionalAttrs stdenv.isDarwin {
|
|
CXX = "clang++";
|
|
CC = "clang";
|
|
CPP = "clang -E";
|
|
CXXCPP = "clang++ -E";
|
|
});
|
|
|
|
in {
|
|
subversion_1_10 = common {
|
|
version = "1.10.7";
|
|
sha256 = "1nhrd8z6c94sc0ryrzpyd98qdn5a5g3x0xv1kdb9da4drrk8y2ww";
|
|
};
|
|
|
|
subversion = common {
|
|
version = "1.14.1";
|
|
sha256 = "1ag1hvcm9q92kgalzbbgcsq9clxnzmbj9nciz9lmabjx4lyajp9c";
|
|
};
|
|
}
|