d240a0da1a
This commit changes the dependencies of stdenv, and clean-up the stdenv story by removing the `defaultStdenv` attribute as well as the `bootStdenv` parameter. Before, the final bootstrapping stage's stdenv was provided by all-packages, which was iterating multiple times over the top-level/default.nix expression, and non-final bootstrapping stages' stdenvs were explicitly specified with the `bootStdenv` parameter. Now, all stages' stdenvs are specified with the `stdenv` parameter. For non-final bootstrapping stages, this is a small change---basically just rename the parameter. For the final stage, top-level/default.nix takes the chosen stdenv and makes the final stage with it. `allPackages` is used to make all bootstrapping stages, final and non-final alike. It's basically the expression of `stage.nix` (along with a few partially-applied default arguments) Note, the make-bootstrap-tools scripts are temporarily broken
65 lines
2.5 KiB
Nix
65 lines
2.5 KiB
Nix
# This file defines the various standard build environments.
|
|
#
|
|
# On Linux systems, the standard build environment consists of
|
|
# Nix-built instances glibc and the `standard' Unix tools, i.e., the
|
|
# Posix utilities, the GNU C compiler, and so on. On other systems,
|
|
# we use the native C library.
|
|
|
|
{ system, allPackages ? import ../top-level, platform, config, crossSystem, lib }:
|
|
|
|
|
|
let
|
|
|
|
|
|
# The native (i.e., impure) build environment. This one uses the
|
|
# tools installed on the system outside of the Nix environment,
|
|
# i.e., the stuff in /bin, /usr/bin, etc. This environment should
|
|
# be used with care, since many Nix packages will not build properly
|
|
# with it (e.g., because they require GNU Make).
|
|
inherit (import ./native { inherit system allPackages config; }) stdenvNative;
|
|
|
|
stdenvNativePkgs = allPackages {
|
|
allowCustomOverrides = false;
|
|
stdenv = stdenvNative;
|
|
noSysDirs = false;
|
|
};
|
|
|
|
|
|
# The Nix build environment.
|
|
stdenvNix = import ./nix {
|
|
inherit config lib;
|
|
stdenv = stdenvNative;
|
|
pkgs = stdenvNativePkgs;
|
|
};
|
|
|
|
inherit (import ./freebsd { inherit system allPackages platform config; }) stdenvFreeBSD;
|
|
|
|
# Linux standard environment.
|
|
inherit (import ./linux { inherit system allPackages platform config lib; }) stdenvLinux;
|
|
|
|
inherit (import ./darwin { inherit system allPackages platform config; }) stdenvDarwin;
|
|
|
|
inherit (import ./cross { inherit system allPackages platform crossSystem config lib; }) stdenvCross stdenvCrossiOS;
|
|
|
|
inherit (import ./custom { inherit system allPackages platform crossSystem config lib; }) stdenvCustom;
|
|
|
|
# Select the appropriate stdenv for the platform `system'.
|
|
in
|
|
if crossSystem != null then
|
|
if crossSystem.useiOSCross or false then stdenvCrossiOS
|
|
else stdenvCross else
|
|
if config ? replaceStdenv then stdenvCustom else
|
|
if system == "i686-linux" then stdenvLinux else
|
|
if system == "x86_64-linux" then stdenvLinux else
|
|
if system == "armv5tel-linux" then stdenvLinux else
|
|
if system == "armv6l-linux" then stdenvLinux else
|
|
if system == "armv7l-linux" then stdenvLinux else
|
|
if system == "mips64el-linux" then stdenvLinux else
|
|
if system == "powerpc-linux" then /* stdenvLinux */ stdenvNative else
|
|
if system == "x86_64-darwin" then stdenvDarwin else
|
|
if system == "x86_64-solaris" then stdenvNix else
|
|
if system == "i686-cygwin" then stdenvNative else
|
|
if system == "x86_64-cygwin" then stdenvNative else
|
|
if system == "x86_64-freebsd" then stdenvFreeBSD else
|
|
stdenvNative
|