796ced2b2a
Diff: https://github.com/agronholm/anyio/compare/3.7.0...3.7.1 Changelog: https://github.com/agronholm/anyio/blob/3.7.1/docs/versionhistory.rst
109 lines
2.1 KiB
Nix
109 lines
2.1 KiB
Nix
{ stdenv
|
|
, lib
|
|
, buildPythonPackage
|
|
, fetchFromGitHub
|
|
, pythonOlder
|
|
|
|
# build-system
|
|
, setuptools
|
|
, setuptools-scm
|
|
|
|
# dependencies
|
|
, exceptiongroup
|
|
, idna
|
|
, sniffio
|
|
|
|
# optionals
|
|
, trio
|
|
|
|
# tests
|
|
, hypothesis
|
|
, psutil
|
|
, pytest-mock
|
|
, pytest-xdist
|
|
, pytestCheckHook
|
|
, trustme
|
|
, uvloop
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "anyio";
|
|
version = "3.7.1";
|
|
format = "pyproject";
|
|
|
|
disabled = pythonOlder "3.7";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "agronholm";
|
|
repo = pname;
|
|
rev = version;
|
|
hash = "sha256-9/pAcVTzw9v57E5l4d8zNyBJM+QNGEuLKrQ0WUBW5xw=";
|
|
};
|
|
|
|
env.SETUPTOOLS_SCM_PRETEND_VERSION = version;
|
|
|
|
nativeBuildInputs = [
|
|
setuptools
|
|
setuptools-scm
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
idna
|
|
sniffio
|
|
] ++ lib.optionals (pythonOlder "3.11") [
|
|
exceptiongroup
|
|
];
|
|
|
|
passthru.optional-dependencies = {
|
|
trio = [
|
|
trio
|
|
];
|
|
};
|
|
|
|
# trustme uses pyopenssl
|
|
doCheck = !(stdenv.isDarwin && stdenv.isAarch64);
|
|
|
|
nativeCheckInputs = [
|
|
hypothesis
|
|
psutil
|
|
pytest-mock
|
|
pytest-xdist
|
|
pytestCheckHook
|
|
trustme
|
|
] ++ lib.optionals (pythonOlder "3.12") [
|
|
uvloop
|
|
] ++ passthru.optional-dependencies.trio;
|
|
|
|
pytestFlagsArray = [
|
|
"-W" "ignore::trio.TrioDeprecationWarning"
|
|
"-m" "'not network'"
|
|
];
|
|
|
|
disabledTests = [
|
|
# INTERNALERROR> AttributeError: 'NonBaseMultiError' object has no attribute '_exceptions'. Did you mean: 'exceptions'?
|
|
"test_exception_group_children"
|
|
"test_exception_group_host"
|
|
"test_exception_group_filtering"
|
|
] ++ lib.optionals stdenv.isDarwin [
|
|
# PermissionError: [Errno 1] Operation not permitted: '/dev/console'
|
|
"test_is_block_device"
|
|
];
|
|
|
|
disabledTestPaths = [
|
|
# lots of DNS lookups
|
|
"tests/test_sockets.py"
|
|
];
|
|
|
|
__darwinAllowLocalNetworking = true;
|
|
|
|
pythonImportsCheck = [ "anyio" ];
|
|
|
|
meta = with lib; {
|
|
changelog = "https://github.com/agronholm/anyio/blob/${src.rev}/docs/versionhistory.rst";
|
|
description = "High level compatibility layer for multiple asynchronous event loop implementations on Python";
|
|
homepage = "https://github.com/agronholm/anyio";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ hexa ];
|
|
};
|
|
}
|