This updates systemd to version v249.4 from version v247.6. Besides the many new features that can be found in the upstream repository they also introduced a bunch of cleanup which ended up requiring a few more patches on our side. a) 0022-core-Handle-lookup-paths-being-symlinks.patch: The way symlinked units were handled was changed in such that the last name of a unit file within one of the unit directories (/run/systemd/system, /etc/systemd/system, ...) is used as the name for the unit. Unfortunately that code didn't take into account that the unit directories themselves could already be symlinks and thus caused all our units to be recognized slightly different. There is an upstream PR for this new patch: https://github.com/systemd/systemd/pull/20479 b) The way the APIVFS is setup has been changed in such a way that we now always have /run. This required a few changes to the confinement tests which did assert that they didn't exist. Instead of adding another patch we can just adopt the upstream behavior. An empty /run doesn't seem harmful. As part of this work I refactored the confinement test just a little bit to allow better debugging of test failures. Previously it would just fail at some point and it wasn't obvious which of the many commands failed or what the unexpected string was. This should now be more obvious. c) Again related to the confinement tests the way a file was tested for being accessible was optimized. Previously systemd would in some situations open a file twice during that check. This was reduced to one operation but required the procfs to be mounted in a units namespace. An upstream bug was filed and fixed. We are now carrying the essential patch to fix that issue until it is backported to a new release (likely only version 250). The good part about this story is that upstream systemd now has a test case that looks very similar to one of our confinement tests. Hopefully that will lead to less friction in the long run. https://github.com/systemd/systemd/issues/20514 https://github.com/systemd/systemd/pull/20515 d) Previously we could grep for dlopen( somewhat reliably but now upstream started using a wrapper around dlopen that is most of the time used with linebreaks. This makes using grep not ergonomic anymore. With this bump we are grepping for anything that looks like a dynamic library name (in contrast to a dlopen(3) call) and replace those instead. That seems more robust. Time will tell if this holds. I tried using coccinelle to patch all those call sites using its tooling but unfornately it does stumble upon the _cleanup_ annotations that are very common in the systemd code. e) We now have some machinery for libbpf support in our systemd build. That being said it doesn't actually work as generating some skeletons doesn't work just yet. It fails with the below error message and is disabled by default (in both minimal and the regular build). > FAILED: src/core/bpf/socket_bind/socket-bind.skel.h > /build/source/tools/build-bpf-skel.py --clang_exec /nix/store/x1bi2mkapk1m0zq2g02nr018qyjkdn7a-clang-wrapper-12.0.1/bin/clang --llvm_strip_exec /nix/store/zm0kqan9qc77x219yihmmisi9g3sg8ns-llvm-12.0.1/bin/llvm-strip --bpftool_exec /nix/store/l6dg8jlbh8qnqa58mshh3d8r6999dk0p-bpftools-5.13.11/bin/bpftool --arch x86_64 ../src/core/bpf/socket_bind/socket-bind.bpf.c src/core/bpf/socket_bind/socket-bind.skel.h > libbpf: elf: socket_bind_bpf is not a valid eBPF object file > Error: failed to open BPF object file: BPF object format invalid > Traceback (most recent call last): > File "/build/source/tools/build-bpf-skel.py", line 128, in <module> > bpf_build(args) > File "/build/source/tools/build-bpf-skel.py", line 92, in bpf_build > gen_bpf_skeleton(bpftool_exec=args.bpftool_exec, > File "/build/source/tools/build-bpf-skel.py", line 63, in gen_bpf_skeleton > skel = subprocess.check_output(bpftool_args, universal_newlines=True) > File "/nix/store/81lwy2hfqj4c1943b1x8a0qsivjhdhw9-python3-3.9.6/lib/python3.9/subprocess.py", line 424, in check_output > return run(*popenargs, stdout=PIPE, timeout=timeout, check=True, > File "/nix/store/81lwy2hfqj4c1943b1x8a0qsivjhdhw9-python3-3.9.6/lib/python3.9/subprocess.py", line 528, in run > raise CalledProcessError(retcode, process.args, > subprocess.CalledProcessError: Command '['/nix/store/l6dg8jlbh8qnqa58mshh3d8r6999dk0p-bpftools-5.13.11/bin/bpftool', 'g', 's', '../src/core/bpf/socket_bind/socket-bind.bpf.o']' returned non-zero exit status 255. > [102/1457] Compiling C object src/journal/libjournal-core.a.p/journald-server.c.oapture output)put)ut) > ninja: build stopped: subcommand failed. f) We do now have support for TPM2 based disk encryption in our systemd build. The actual bits and pieces to make use of that are missing but there are various ongoing efforts in that direction. There is also the story about systemd in our initrd to enable this being used for root volumes. None of this will yet work out of the box but we can start improving on that front. g) FIDO2 support was added systemd and consequently we can now use that. Just with TPM2 there hasn't been any integration work with NixOS and instead this just adds that capability to work on that. Co-Authored-By: Jörg Thalheim <joerg@thalheim.io>
162 lines
6.1 KiB
Nix
162 lines
6.1 KiB
Nix
import ./make-test-python.nix {
|
|
name = "systemd-confinement";
|
|
|
|
machine = { pkgs, lib, ... }: let
|
|
testServer = pkgs.writeScript "testserver.sh" ''
|
|
#!${pkgs.runtimeShell}
|
|
export PATH=${lib.escapeShellArg "${pkgs.coreutils}/bin"}
|
|
${lib.escapeShellArg pkgs.runtimeShell} 2>&1
|
|
echo "exit-status:$?"
|
|
'';
|
|
|
|
testClient = pkgs.writeScriptBin "chroot-exec" ''
|
|
#!${pkgs.runtimeShell} -e
|
|
output="$(echo "$@" | nc -NU "/run/test$(< /teststep).sock")"
|
|
ret="$(echo "$output" | sed -nre '$s/^exit-status:([0-9]+)$/\1/p')"
|
|
echo "$output" | head -n -1
|
|
exit "''${ret:-1}"
|
|
'';
|
|
|
|
mkTestStep = num: { config ? {}, testScript }: {
|
|
systemd.sockets."test${toString num}" = {
|
|
description = "Socket for Test Service ${toString num}";
|
|
wantedBy = [ "sockets.target" ];
|
|
socketConfig.ListenStream = "/run/test${toString num}.sock";
|
|
socketConfig.Accept = true;
|
|
};
|
|
|
|
systemd.services."test${toString num}@" = {
|
|
description = "Confined Test Service ${toString num}";
|
|
confinement = (config.confinement or {}) // { enable = true; };
|
|
serviceConfig = (config.serviceConfig or {}) // {
|
|
ExecStart = testServer;
|
|
StandardInput = "socket";
|
|
};
|
|
} // removeAttrs config [ "confinement" "serviceConfig" ];
|
|
|
|
__testSteps = lib.mkOrder num (''
|
|
machine.succeed("echo ${toString num} > /teststep")
|
|
'' + testScript);
|
|
};
|
|
|
|
in {
|
|
imports = lib.imap1 mkTestStep [
|
|
{ config.confinement.mode = "chroot-only";
|
|
testScript = ''
|
|
with subtest("chroot-only confinement"):
|
|
paths = machine.succeed('chroot-exec ls -1 / | paste -sd,').strip()
|
|
assert_eq(paths, "bin,nix,run")
|
|
uid = machine.succeed('chroot-exec id -u').strip()
|
|
assert_eq(uid, "0")
|
|
machine.succeed("chroot-exec chown 65534 /bin")
|
|
'';
|
|
}
|
|
{ testScript = ''
|
|
with subtest("full confinement with APIVFS"):
|
|
machine.fail("chroot-exec ls -l /etc")
|
|
machine.fail("chroot-exec chown 65534 /bin")
|
|
assert_eq(machine.succeed('chroot-exec id -u').strip(), "0")
|
|
machine.succeed("chroot-exec chown 0 /bin")
|
|
'';
|
|
}
|
|
{ config.serviceConfig.BindReadOnlyPaths = [ "/etc" ];
|
|
testScript = ''
|
|
with subtest("check existence of bind-mounted /etc"):
|
|
passwd = machine.succeed('chroot-exec cat /etc/passwd').strip()
|
|
assert len(passwd) > 0, "/etc/passwd must not be empty"
|
|
'';
|
|
}
|
|
{ config.serviceConfig.User = "chroot-testuser";
|
|
config.serviceConfig.Group = "chroot-testgroup";
|
|
testScript = ''
|
|
with subtest("check if User/Group really runs as non-root"):
|
|
machine.succeed("chroot-exec ls -l /dev")
|
|
uid = machine.succeed('chroot-exec id -u').strip()
|
|
assert uid != "0", "UID of chroot-testuser shouldn't be 0"
|
|
machine.fail("chroot-exec touch /bin/test")
|
|
'';
|
|
}
|
|
(let
|
|
symlink = pkgs.runCommand "symlink" {
|
|
target = pkgs.writeText "symlink-target" "got me\n";
|
|
} "ln -s \"$target\" \"$out\"";
|
|
in {
|
|
config.confinement.packages = lib.singleton symlink;
|
|
testScript = ''
|
|
with subtest("check if symlinks are properly bind-mounted"):
|
|
machine.fail("chroot-exec test -e /etc")
|
|
text = machine.succeed('chroot-exec cat ${symlink}').strip()
|
|
assert_eq(text, "got me")
|
|
'';
|
|
})
|
|
{ config.serviceConfig.User = "chroot-testuser";
|
|
config.serviceConfig.Group = "chroot-testgroup";
|
|
config.serviceConfig.StateDirectory = "testme";
|
|
testScript = ''
|
|
with subtest("check if StateDirectory works"):
|
|
machine.succeed("chroot-exec touch /tmp/canary")
|
|
machine.succeed('chroot-exec "echo works > /var/lib/testme/foo"')
|
|
machine.succeed('test "$(< /var/lib/testme/foo)" = works')
|
|
machine.succeed("test ! -e /tmp/canary")
|
|
'';
|
|
}
|
|
{ testScript = ''
|
|
with subtest("check if /bin/sh works"):
|
|
machine.succeed(
|
|
"chroot-exec test -e /bin/sh",
|
|
'test "$(chroot-exec \'/bin/sh -c "echo bar"\')" = bar',
|
|
)
|
|
'';
|
|
}
|
|
{ config.confinement.binSh = null;
|
|
testScript = ''
|
|
with subtest("check if suppressing /bin/sh works"):
|
|
machine.succeed("chroot-exec test ! -e /bin/sh")
|
|
machine.succeed('test "$(chroot-exec \'/bin/sh -c "echo foo"\')" != foo')
|
|
'';
|
|
}
|
|
{ config.confinement.binSh = "${pkgs.hello}/bin/hello";
|
|
testScript = ''
|
|
with subtest("check if we can set /bin/sh to something different"):
|
|
machine.succeed("chroot-exec test -e /bin/sh")
|
|
machine.succeed('test "$(chroot-exec /bin/sh -g foo)" = foo')
|
|
'';
|
|
}
|
|
{ config.environment.FOOBAR = pkgs.writeText "foobar" "eek\n";
|
|
testScript = ''
|
|
with subtest("check if only Exec* dependencies are included"):
|
|
machine.succeed('test "$(chroot-exec \'cat "$FOOBAR"\')" != eek')
|
|
'';
|
|
}
|
|
{ config.environment.FOOBAR = pkgs.writeText "foobar" "eek\n";
|
|
config.confinement.fullUnit = true;
|
|
testScript = ''
|
|
with subtest("check if all unit dependencies are included"):
|
|
machine.succeed('test "$(chroot-exec \'cat "$FOOBAR"\')" = eek')
|
|
'';
|
|
}
|
|
];
|
|
|
|
options.__testSteps = lib.mkOption {
|
|
type = lib.types.lines;
|
|
description = "All of the test steps combined as a single script.";
|
|
};
|
|
|
|
config.environment.systemPackages = lib.singleton testClient;
|
|
|
|
config.users.groups.chroot-testgroup = {};
|
|
config.users.users.chroot-testuser = {
|
|
isSystemUser = true;
|
|
description = "Chroot Test User";
|
|
group = "chroot-testgroup";
|
|
};
|
|
};
|
|
|
|
testScript = { nodes, ... }: ''
|
|
def assert_eq(a, b):
|
|
assert a == b, f"{a} != {b}"
|
|
|
|
machine.wait_for_unit("multi-user.target")
|
|
'' + nodes.machine.config.__testSteps;
|
|
}
|