the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
107 lines
2.5 KiB
Nix
107 lines
2.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.atd;
|
|
|
|
inherit (pkgs) at;
|
|
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.atd.enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable the {command}`at` daemon, a command scheduler.
|
|
'';
|
|
};
|
|
|
|
services.atd.allowEveryone = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to make {file}`/var/spool/at{jobs,spool}`
|
|
writeable by everyone (and sticky). This is normally not
|
|
needed since the {command}`at` commands are
|
|
setuid/setgid `atd`.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
# Not wrapping "batch" because it's a shell script (kernel drops perms
|
|
# anyway) and it's patched to invoke the "at" setuid wrapper.
|
|
security.wrappers = builtins.listToAttrs (
|
|
map (program: { name = "${program}"; value = {
|
|
source = "${at}/bin/${program}";
|
|
owner = "atd";
|
|
group = "atd";
|
|
setuid = true;
|
|
setgid = true;
|
|
};}) [ "at" "atq" "atrm" ]);
|
|
|
|
environment.systemPackages = [ at ];
|
|
|
|
security.pam.services.atd = {};
|
|
|
|
users.users.atd =
|
|
{
|
|
uid = config.ids.uids.atd;
|
|
group = "atd";
|
|
description = "atd user";
|
|
home = "/var/empty";
|
|
};
|
|
|
|
users.groups.atd.gid = config.ids.gids.atd;
|
|
|
|
systemd.services.atd = {
|
|
description = "Job Execution Daemon (atd)";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
path = [ at ];
|
|
|
|
preStart = ''
|
|
# Snippets taken and adapted from the original `install' rule of
|
|
# the makefile.
|
|
|
|
# We assume these values are those actually used in Nixpkgs for
|
|
# `at'.
|
|
spooldir=/var/spool/atspool
|
|
jobdir=/var/spool/atjobs
|
|
etcdir=/etc/at
|
|
|
|
install -dm755 -o atd -g atd "$etcdir"
|
|
spool_and_job_dir_perms=${if cfg.allowEveryone then "1777" else "1770"}
|
|
install -dm"$spool_and_job_dir_perms" -o atd -g atd "$spooldir" "$jobdir"
|
|
if [ ! -f "$etcdir"/at.deny ]; then
|
|
touch "$etcdir"/at.deny
|
|
chown root:atd "$etcdir"/at.deny
|
|
chmod 640 "$etcdir"/at.deny
|
|
fi
|
|
if [ ! -f "$jobdir"/.SEQ ]; then
|
|
touch "$jobdir"/.SEQ
|
|
chown atd:atd "$jobdir"/.SEQ
|
|
chmod 600 "$jobdir"/.SEQ
|
|
fi
|
|
'';
|
|
|
|
script = "atd";
|
|
|
|
serviceConfig.Type = "forking";
|
|
};
|
|
};
|
|
}
|