Update: * glslang * spirv-headers * spirv-toools * vulkan-extension-layer * vulkan-headers * vulkan-loader * vulkan-tools * vulkan-tools-lunarg * vulkan-validation-layers Fixes #161060
85 lines
2.1 KiB
Nix
85 lines
2.1 KiB
Nix
{ lib
|
|
, callPackage
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, pkgconfig
|
|
, glslang
|
|
, libffi
|
|
, libX11
|
|
, libXau
|
|
, libxcb
|
|
, libXdmcp
|
|
, libXrandr
|
|
, spirv-headers
|
|
, spirv-tools
|
|
, vulkan-headers
|
|
, wayland
|
|
}:
|
|
|
|
let
|
|
robin-hood-hashing = callPackage ./robin-hood-hashing.nix {};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "vulkan-validation-layers";
|
|
version = "1.3.211.0";
|
|
|
|
# If we were to use "dev" here instead of headers, the setupHook would be
|
|
# placed in that output instead of "out".
|
|
outputs = ["out" "headers"];
|
|
outputInclude = "headers";
|
|
|
|
src = (assert (lib.all (pkg: pkg.version == version) [vulkan-headers glslang spirv-tools spirv-headers]);
|
|
fetchFromGitHub {
|
|
owner = "KhronosGroup";
|
|
repo = "Vulkan-ValidationLayers";
|
|
rev = "sdk-${version}";
|
|
sha256 = "sha256-NGpFfekZtB0rvnGxYVDo808xzgBuo8ZC4bjXjQnTpxU=";
|
|
});
|
|
|
|
# Include absolute paths to layer libraries in their associated
|
|
# layer definition json files.
|
|
postPatch = ''
|
|
sed "s|\([[:space:]]*set(INSTALL_DEFINES \''${INSTALL_DEFINES} -DRELATIVE_LAYER_BINARY=\"\)\(\$<TARGET_FILE_NAME:\''${TARGET_NAME}>\")\)|\1$out/lib/\2|" -i layers/CMakeLists.txt
|
|
'';
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
pkgconfig
|
|
];
|
|
|
|
buildInputs = [
|
|
libX11
|
|
libXau
|
|
libXdmcp
|
|
libXrandr
|
|
libffi
|
|
libxcb
|
|
spirv-tools
|
|
vulkan-headers
|
|
wayland
|
|
];
|
|
|
|
cmakeFlags = [
|
|
"-DGLSLANG_INSTALL_DIR=${glslang}"
|
|
"-DSPIRV_HEADERS_INSTALL_DIR=${spirv-headers}"
|
|
"-DROBIN_HOOD_HASHING_INSTALL_DIR=${robin-hood-hashing}"
|
|
"-DBUILD_LAYER_SUPPORT_FILES=ON"
|
|
"-DPKG_CONFIG_EXECUTABLE=${pkgconfig}/bin/pkg-config"
|
|
# Hide dev warnings that are useless for packaging
|
|
"-Wno-dev"
|
|
];
|
|
|
|
# Tests require access to vulkan-compatible GPU, which isn't
|
|
# available in Nix sandbox. Fails with VK_ERROR_INCOMPATIBLE_DRIVER.
|
|
doCheck = false;
|
|
|
|
meta = with lib; {
|
|
description = "The official Khronos Vulkan validation layers";
|
|
homepage = "https://github.com/KhronosGroup/Vulkan-ValidationLayers";
|
|
platforms = platforms.linux;
|
|
license = licenses.asl20;
|
|
maintainers = [ maintainers.ralith ];
|
|
};
|
|
}
|