9833d56c24
Done with the help of https://github.com/Mindavi/nixpkgs-mark-broken Tool is still WIP but this is one of the first results. I manually audited the results and removed some results that were not valid. Note that some of these packages maybe should have more constrained platforms set instead of broken set, but I think not being perfectly correct is better than just keep trying to build all these things and never succeeding. Some observations: - Some darwin builds require XCode tools - aarch64-linux builds sometimes suffer from using gcc9 - gcc9 is getting older and misses some new libraries/features - Sometimes tools try to do system detection or expect some explicit settings for platforms that are not x86_64-linux
42 lines
1.5 KiB
Nix
42 lines
1.5 KiB
Nix
{ lib, stdenv, buildGoPackage, fetchFromGitHub, fetchpatch, pkg-config, cctools, Hypervisor, vmnet }:
|
|
|
|
buildGoPackage rec {
|
|
pname = "docker-machine-xhyve";
|
|
version = "0.4.0";
|
|
|
|
goPackagePath = "github.com/zchee/docker-machine-driver-xhyve";
|
|
|
|
# https://github.com/machine-drivers/docker-machine-driver-xhyve/pull/225
|
|
patches = fetchpatch {
|
|
url = "https://github.com/machine-drivers/docker-machine-driver-xhyve/commit/546256494bf2ccc33e4125bf45f504b0e3027d5a.patch";
|
|
sha256 = "1i8wxqccqkxvqrbsyd0g9s0kdskd8xi2jv0c1bji9aj4rq0a8cgz";
|
|
};
|
|
|
|
preBuild = ''
|
|
make -C go/src/${goPackagePath} CC=${stdenv.cc}/bin/cc LIBTOOL=${cctools}/bin/libtool GIT_CMD=: lib9p
|
|
export CGO_CFLAGS=-I$(pwd)/go/src/${goPackagePath}/vendor/github.com/jceel/lib9p
|
|
export CGO_LDFLAGS=$(pwd)/go/src/${goPackagePath}/vendor/build/lib9p/lib9p.a
|
|
'';
|
|
tags = [ "lib9p" ];
|
|
|
|
src = fetchFromGitHub {
|
|
rev = "v${version}";
|
|
owner = "machine-drivers";
|
|
repo = "docker-machine-driver-xhyve";
|
|
sha256 = "0000v97fr8xc5b39v44hsa87wrbk4bcwyaaivxv4hxlf4vlgg863";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkg-config ];
|
|
buildInputs = [ Hypervisor vmnet ];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/machine-drivers/docker-machine-driver-xhyve";
|
|
description = "Xhyve driver for docker-machine";
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ periklis ];
|
|
platforms = platforms.darwin;
|
|
# never built on aarch64-darwin since first introduction in nixpkgs
|
|
broken = stdenv.isDarwin && stdenv.isAarch64;
|
|
};
|
|
}
|