os/modules/user/home.nix

{
  config,
  pkgs,
  lib,
  ...
}:
with lib; let
  psCfg = config.pub-solar;
  xdg = config.home-manager.users."${psCfg.user.name}".xdg;
in {
  imports = [
    ./session-variables.nix
  ];

  home-manager.users."${psCfg.user.name}" = {
    # Let Home Manager install and manage itself.
    programs.home-manager.enable = true;

    # Home Manager needs a bit of information about you and the
    # paths it should manage.
    home.username = psCfg.user.name;
    home.homeDirectory = "/home/${psCfg.user.name}";
    home.stateVersion = "22.11";

    programs.dircolors.enable = true;

    xdg.enable = true;
    xdg.mime.enable = true;
    xdg.mimeApps = import ./mimeapps.nix;

    xdg.configFile."dircolors".source = ./.config/dircolors;

    xdg.dataFile."shell.nix.tmpl" = {
      text = ''
        let
          unstable = import (fetchTarball https://github.com/nixos/nixpkgs/archive/nixos-unstable.tar.gz) { };
        in
        { nixpkgs ? import <nixpkgs> {} }:
        with nixpkgs; mkShell {
          buildInputs = [
          ];
        }
      '';
      target = "nvim/templates/shell.nix.tmpl";
    };

    # Allow unfree packages only on a user basis, not on a system-wide basis
    xdg.configFile."nixpkgs/config.nix".text = " { allowUnfree = true; } ";
  };
}