os/hosts/frikandel/website.nix

{
  pkgs,
  lib,
  ...
}: let
  bbeu = pkgs.stdenv.mkDerivation {
    name = "benjaminbaedorf.eu";
    src = pkgs.fetchgit {
      url = "https://git.pub.solar/b12f/benjaminbaedorf.eu.git";
      sparseCheckout = [
        "fonts"
        "cows.jpg"
        "fonts.css"
        "index.html"
        "public-pgp-benjamin-baedorf.asc"
      ];
      hash = "sha256-c5nU9zqrHgD+dCXdXXcS9xJIaGueyXQpuwSqv0aSLM0=";
    };
    installPhase = ''
      mkdir -p $out
      cp -r * $out/
    '';
  };
in {
  security.acme.certs = {
    "benjaminbaedorf.eu" = {};
    "b12f.io" = {};
  };

  services.nginx.virtualHosts = {
    "benjaminbaedorf.eu" = {
      forceSSL = true;
      useACMEHost = "benjaminbaedorf.eu";
      locations."/".return = "302 https://b12f.io$request_uri";
    };

    "b12f.io" = {
      forceSSL = true;
      useACMEHost = "b12f.io";

      locations."/" = {
        root = bbeu;
        index = "index.html";
        tryFiles = "$uri $uri/ =404";
      };
    };
  };
}