os/overlays/default.nix

{
  self,
  inputs,
  ...
}: {
  flake = {
    nixosModules = {
      overlays = {...}: {
        nixpkgs.overlays = [
          inputs.deno2nix.overlays.default
          inputs.nixd.overlays.default
          inputs.invoiceplane-template.overlays.default
          inputs.mezza-biz.overlays.default

          (final: prev: (import ../pkgs { pkgs = final; }))

          (final: prev: let
            unstable = import inputs.nixpkgs-unstable {system = prev.system;};
            master = import inputs.nixpkgs-master {system = prev.system;};
          in {
            factorio-headless = master.factorio-headless;
            authelia = master.authelia;
            paperless-ngx = master.paperless-ngx.overrideAttrs (oa: {
             doCheck = false;
             doInstallCheck = false;
            });
            waybar = master.waybar;
            firefox = unstable.firefox;
            nix-inspect = unstable.nix-inspect;
            # nix = unstable.lix;

            adlist = inputs.adblock-unbound.packages.${prev.system};

            haskellPackages =
              prev.haskellPackages.override
              (old: {
                overrides = prev.lib.composeExtensions (old.overrides or (_: _: {})) (hfinal: hprev: let
                  version = prev.lib.replaceChars ["."] [""] prev.ghc.version;
                in {
                  # same for haskell packages, matching ghc versions
                  inherit
                    (unstable.haskell.packages."ghc${version}")
                    haskell-language-server
                    ;
                });
              });

            vimPlugins = prev.vimPlugins // {inherit (unstable.vimPlugins) nvim-lspconfig;};
          })

          (import ./rnix-lsp.nix)
          (import ./neovim-plugins.nix)

          (final: prev: {
            b12f-io = prev.stdenv.mkDerivation {
              name = "b12f.io";
              inherit (prev.sources.b12f-io-nvfetcher) version src;
              installPhase = ''
                mkdir -p $out
                cp -r * $out/
                cp -r fonts cows.jpg fonts.css index.html bbeu-public.key $out/
              '';
            };
          })
        ];
      };
    };
  };
}