niXtended/nixos.nix

{ pkgs, inputs, modulesPath, ... }:
let
  True = { enable = true; };
  False = { enable = false; };
in with pkgs; {
  imports = [
    (modulesPath + "/installer/cd-dvd/installation-cd-minimal.nix")
    inputs.stylix.nixosModules.stylix
  ];
  # SYSTEM
  boot = {
    kernelPackages = pkgs.linuxPackages_zen;
    loader.timeout = lib.mkDefault 0;
  };
  networking = {
    wireless = False;
    networkmanager = True // { insertNameservers = [ "1.1.1.1" "1.0.0.1" ]; };
  };

  # PACKAGES
  nixpkgs.config = {
    allowBroken = true;
    allowUnfree = true;
  };
  nix.settings.experimental-features = [ "nix-command" "flakes" ];
  programs = {
    git = True // { package = gitMinimal; };
    fish = True // {
      interactiveShellInit = "fish_vi_key_bindings";
      shellAliases = { e = "${helix}/bin/hx"; };
    };
    starship = True // {
      settings = {
        add_newline = true;
        format = lib.concatStrings [
          "$username"
          "$directory"
          "$git_branch"
          "$cmd_duration"
          "$line_break"
          "$character"
        ];
        shell = {
          fish_indicator = "[fish]($style)";
          style = "bold fg:purple";
        };
        username = {
          style_user = "bold red";
          style_root = "bold red";
          format = "[$user]($style) in ";
          show_always = true;
        };
        directory = {
          format = "[$path]($style) [$read_only]($read_only_style)";
          style = "bold fg:blue";
          read_only = "[󰌾] ";
          read_only_style = "bold red";
          home_symbol = "~~";
          truncation_length = 2;
          truncation_symbol = "../";
        };
        git_branch = {
          format = "on [$symbol$branch]($style) ";
          style = "bold italic fg:green";
          symbol = " ";
          truncation_length = 4;
          truncation_symbol = "";
          disabled = false;
        };
        cmd_duration = {
          min_time = 1000;
          format = "took [$duration](bold fg:yellow)";
          disabled = false;
        };
        character = {
          format = "$symbol ";
          success_symbol = "[❯](bold green)";
          error_symbol = "[❯](bold red)";
          vimcmd_symbol = "[❮](bold yellow)";
          vimcmd_replace_one_symbol = "[❯](bold purple)";
          vimcmd_replace_symbol = "[❯](bold purple)";
          vimcmd_visual_symbol = "[❯](bold yellow)";
          disabled = false;
        };
      };
    };
  };

  # THEME
  stylix = True // { # COLORIZE !!!
    autoEnable = false;
    base16Scheme = "${base16-schemes}/share/themes/horizon-terminal-dark.yaml";
    targets = {
      console = True;
      fish = True;
    };
  };
}