ultima/modules/home/themes/stylix/default.nix

{ x, pkgs, lib, config, inputs, True, False, ... }:

with lib;
with x;
let
  cfg = config.module.themes.stylix;
  wal = inputs.design;
in {
  options = {
    module.themes.stylix = {
      enable = mkBool;
      theme = mkOpt.str;
      image = mkOpt.str;
      cursor = {
        bg = mkOpt.str;
        ol = mkOpt.str;
        ac = mkOpt.str;
      };
    };
  };

  imports = with inputs; [
    stylix.homeManagerModules.stylix
    ../../../colors.nix
  ];
  config = mkIf cfg.enable {
    stylix = True // {
      autoEnable = false;
      image = "${wal}/wallpapers/paradise/${cfg.image}.jpg";
      cursor = with inputs.cursors; {
        size = 16;
        name = "GoogleDot-Custom";
        package = packages.${pkgs.system}.google-cursor.override {
          background_color = cfg.cursor.bg;
          outline_color = cfg.cursor.ol;
          accent_color = cfg.cursor.ac;
        };
      };
      fonts = let
        jetBrains = { name = "JetBrainsMono Nerd Font"; };
        package = with pkgs.nerd-fonts;
          (jetbrains-mono.overrideAttrs (oldAttrs: {
            installPhase = ''
              runHook preInstall
              dst_opentype=$out/share/fonts/opentype/NerdFonts
              dst_truetype=$out/share/fonts/truetype/NerdFonts
              find -name \*.otf -exec mkdir -p $dst_opentype \; -exec cp -p {} $dst_opentype \;
              find -name \*.ttf -exec mkdir -p $dst_truetype \; -exec cp -p {} $dst_truetype \;
              runHook postInstall
            '';
          }));
      in with config.stylix.fonts; {
        monospace = jetBrains // { inherit package; };
        serif = monospace;
        emoji = monospace;
        sizes = {
          desktop = 10;
          popups = 10;
          applications = 12;
          terminal = 12;
        };
      };
      targets = {
        # CLI
        tmux = True;
        fish = True;
        nushell = True;
        # WM
        hyprland = True;
        sway = True;
        foot = True;
        kitty = True;
        mako = False;
        # TOOLS
        nixvim = True;
        yazi = True;
        fzf = True;
        bat = True;
        mangohud = True;
        # GUI
        vesktop = True;
        qutebrowser = True;
        firefox = True;
        gtk = True;
      };
    };
  };
}