os/modules/core/hibernation.nix

{
  config,
  pkgs,
  lib,
  ...
}:
let
  cfg = config.pub-solar.core.hibernation;
  inherit (lib) mkOption types mkIf;
in
{
  options.pub-solar.core.hibernation = {
    enable = mkOption {
      type = types.bool;
      default = false;
      description = "Whether the device can hibernate. This creates a swapfile at /swapfile.";
    };

    resumeDevice = mkOption {
      type = types.nullOr types.str;
      default = null;
      description = "The location of the hibernation resume swap file.";
    };

    resumeOffset = mkOption {
      type = types.nullOr types.int;
      default = null;
      description = "The swap file offset. Can be found by running `filefrag -v $swap_file_location`. See https://wiki.archlinux.org/title/Power_management/Suspend_and_hibernate#Hibernation_into_swap_file";
    };
  };

  config = {
    boot = mkIf cfg.enable {
      resumeDevice = mkIf (cfg.resumeDevice != null) cfg.resumeDevice;
      kernelParams = mkIf (cfg.resumeOffset != null) [
        "resume_offset=${builtins.toString cfg.resumeOffset}"
      ];
    };
  };
}